pkgs/development/libraries/physics/hepmc3/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   cmake,
   6   coreutils,
   7   python,
   8   root,
   9 }:
  10
  11 let
  12   pythonVersion = with lib.versions; "${major python.version}${minor python.version}";
  13   withPython = python != null;
  14   # ensure that root is built with the same python interpreter, as it links against numpy
  15   root_py = if withPython then root.override { python3 = python; } else root;
  16 in
  17
  18 stdenv.mkDerivation rec {
  19   pname = "hepmc3";
  20   version = "3.3.0";
  21
  22   src = fetchurl {
  23     url = "http://hepmc.web.cern.ch/hepmc/releases/HepMC3-${version}.tar.gz";
  24     sha256 = "sha256-b4dgke3PfubQwNsE4IAFbonvwaYavmI1XZfOjnNXadY=";
  25   };
  26
  27   nativeBuildInputs = [
  28     cmake
  29   ] ++ lib.optional withPython python.pkgs.pythonImportsCheckHook;
  30
  31   buildInputs = [
  32     root_py
  33   ] ++ lib.optional withPython python;
  34
  35   # error: invalid version number in 'MACOSX_DEPLOYMENT_TARGET=11.0'
  36   preConfigure =
  37     lib.optionalString
  38       (stdenv.hostPlatform.isDarwin && lib.versionAtLeast stdenv.hostPlatform.darwinMinVersion "11")
  39       ''
  40         MACOSX_DEPLOYMENT_TARGET=10.16
  41       '';
  42
  43   cmakeFlags =
  44     [
  45       "-DHEPMC3_CXX_STANDARD=17"
  46       "-DHEPMC3_ENABLE_PYTHON=${if withPython then "ON" else "OFF"}"
  47     ]
  48     ++ lib.optionals withPython [
  49       "-DHEPMC3_PYTHON_VERSIONS=${if python.isPy3k then "3.X" else "2.X"}"
  50       "-DHEPMC3_Python_SITEARCH${pythonVersion}=${placeholder "out"}/${python.sitePackages}"
  51     ];
  52
  53   postInstall = ''
  54     substituteInPlace "$out"/bin/HepMC3-config \
  55       --replace-fail '$(greadlink' '$(${coreutils}/bin/readlink' \
  56       --replace-fail '$(readlink' '$(${coreutils}/bin/readlink'
  57   '';
  58
  59   pythonImportsCheck = [ "pyHepMC3" ];
  60
  61   meta = with lib; {
  62     description = "HepMC package is an object oriented, C++ event record for High Energy Physics Monte Carlo generators and simulation";
  63     mainProgram = "HepMC3-config";
  64     license = licenses.gpl3;
  65     homepage = "http://hepmc.web.cern.ch/hepmc/";
  66     platforms = platforms.unix;
  67     maintainers = with maintainers; [ veprbl ];
  68   };
  69 }