pkgs/development/libraries/physics/lhapdf/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   python,
   6   makeWrapper,
   7 }:
   8
   9 stdenv.mkDerivation rec {
  10   pname = "lhapdf";
  11   version = "6.5.4";
  12
  13   src = fetchurl {
  14     url = "https://www.hepforge.org/archive/lhapdf/LHAPDF-${version}.tar.gz";
  15     sha256 = "sha256-JEOksyzDsFl8gki9biVwOs6ckaeiU8X2CxtUKO+chp4=";
  16   };
  17
  18   # The Apple SDK only exports locale_t from xlocale.h whereas glibc
  19   # had decided that xlocale.h should be a part of locale.h
  20   postPatch = lib.optionalString (stdenv.hostPlatform.isDarwin && stdenv.cc.isGNU) ''
  21     substituteInPlace src/GridPDF.cc --replace '#include <locale>' '#include <xlocale.h>'
  22   '';
  23
  24   nativeBuildInputs =
  25     [ makeWrapper ]
  26     ++ lib.optionals (python != null && lib.versionAtLeast python.version "3.10") [
  27       python.pkgs.cython
  28     ];
  29   buildInputs = [ python ];
  30
  31   configureFlags = lib.optionals (python == null) [ "--disable-python" ];
  32
  33   preBuild = lib.optionalString (python != null && lib.versionAtLeast python.version "3.10") ''
  34     rm wrappers/python/lhapdf.cpp
  35   '';
  36
  37   enableParallelBuilding = true;
  38
  39   passthru = {
  40     pdf_sets = import ./pdf_sets.nix { inherit lib stdenv fetchurl; };
  41   };
  42
  43   postInstall = ''
  44     wrapProgram $out/bin/lhapdf --prefix PYTHONPATH : "$(toPythonPath "$out")"
  45   '';
  46
  47   meta = with lib; {
  48     description = "General purpose interpolator, used for evaluating Parton Distribution Functions from discretised data files";
  49     license = licenses.gpl2;
  50     homepage = "http://lhapdf.hepforge.org";
  51     platforms = platforms.unix;
  52     maintainers = with maintainers; [ veprbl ];
  53   };
  54 }