pkgs/development/libraries/qt-5/modules/qtwebkit.nix

   1 {
   2   qtModule,
   3   stdenv,
   4   lib,
   5   fetchurl,
   6   qtbase,
   7   qtdeclarative,
   8   qtlocation,
   9   qtmultimedia,
  10   qtsensors,
  11   qtwebchannel,
  12   fontconfig,
  13   libwebp,
  14   libxml2,
  15   libxslt,
  16   sqlite,
  17   systemd,
  18   glib,
  19   gst_all_1,
  20   cmake,
  21   bison,
  22   flex,
  23   gdb,
  24   gperf,
  25   perl,
  26   pkg-config,
  27   python3,
  28   ruby,
  29 }:
  30
  31 let
  32   hyphen = stdenv.mkDerivation rec {
  33     pname = "hyphen";
  34     version = "2.8.8";
  35     src = fetchurl {
  36       url = "http://dev-www.libreoffice.org/src/5ade6ae2a99bc1e9e57031ca88d36dad-hyphen-${version}.tar.gz";
  37       sha256 = "304636d4eccd81a14b6914d07b84c79ebb815288c76fe027b9ebff6ff24d5705";
  38     };
  39     postPatch = ''
  40       patchShebangs tests
  41     '';
  42     buildInputs = [ perl ];
  43   };
  44 in
  45 qtModule {
  46   pname = "qtwebkit";
  47   propagatedBuildInputs = [
  48     qtbase
  49     qtdeclarative
  50     qtlocation
  51     qtsensors
  52     qtwebchannel
  53   ] ++ lib.optional stdenv.hostPlatform.isDarwin qtmultimedia;
  54   buildInputs = [
  55     fontconfig
  56     libwebp
  57     libxml2
  58     libxslt
  59     sqlite
  60     glib
  61     gst_all_1.gstreamer
  62     gst_all_1.gst-plugins-base
  63     hyphen
  64   ];
  65   nativeBuildInputs = [
  66     bison
  67     flex
  68     gdb
  69     gperf
  70     perl
  71     pkg-config
  72     python3
  73     ruby
  74     cmake
  75   ];
  76
  77   cmakeFlags =
  78     [ "-DPORT=Qt" ]
  79     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  80       "-DQt5Multimedia_DIR=${lib.getDev qtmultimedia}/lib/cmake/Qt5Multimedia"
  81       "-DQt5MultimediaWidgets_DIR=${lib.getDev qtmultimedia}/lib/cmake/Qt5MultimediaWidgets"
  82       "-DMACOS_FORCE_SYSTEM_XML_LIBRARIES=OFF"
  83     ];
  84
  85   env.NIX_CFLAGS_COMPILE = toString (
  86     [
  87       # with gcc7 this warning blows the log over Hydra's limit
  88       "-Wno-expansion-to-defined"
  89     ]
  90     # with gcc8, -Wclass-memaccess became part of -Wall and this too exceeds the logging limit
  91     ++ lib.optional stdenv.cc.isGNU "-Wno-class-memaccess"
  92     # with clang this warning blows the log over Hydra's limit
  93     ++ lib.optional stdenv.hostPlatform.isDarwin "-Wno-inconsistent-missing-override"
  94     ++ lib.optional (
  95       !stdenv.hostPlatform.isDarwin
  96     ) ''-DNIXPKGS_LIBUDEV="${lib.getLib systemd}/lib/libudev"''
  97   );
  98
  99   doCheck = false; # fails 13 out of 13 tests (ctest)
 100
 101   # remove forbidden references to $TMPDIR
 102   preFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
 103     patchelf --shrink-rpath --allowed-rpath-prefixes "$NIX_STORE" "$out"/libexec/*
 104   '';
 105
 106   enableParallelBuilding = true;
 107
 108   meta = {
 109     maintainers = with lib.maintainers; [
 110       abbradar
 111       periklis
 112     ];
 113     knownVulnerabilities = [
 114       "QtWebkit upstream is unmaintained and receives no security updates, see https://blogs.gnome.org/mcatanzaro/2022/11/04/stop-using-qtwebkit/"
 115     ];
 116   };
 117 }