pkgs/development/libraries/xapian/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , autoreconfHook
   5 , libuuid
   6 , zlib
   7
   8 # tests
   9 , mu
  10 , perlPackages
  11 , python3
  12 , xapian-omega
  13 }:
  14
  15 let
  16   generic = version: hash: stdenv.mkDerivation {
  17     pname = "xapian";
  18     inherit version;
  19     passthru = { inherit version; };
  20
  21     src = fetchurl {
  22       url = "https://oligarchy.co.uk/xapian/${version}/xapian-core-${version}.tar.xz";
  23       inherit hash;
  24     };
  25
  26     outputs = [ "out" "man" "doc" ];
  27
  28     buildInputs = [ libuuid zlib ];
  29     nativeBuildInputs = [ autoreconfHook ];
  30
  31     enableParallelBuilding = true;
  32
  33     doCheck = true;
  34
  35     env = {
  36       AUTOMATED_TESTING = true; # https://trac.xapian.org/changeset/8be35f5e1/git
  37     } // lib.optionalAttrs stdenv.hostPlatform.is32bit {
  38       NIX_CFLAGS_COMPILE = "-fpermissive";
  39     };
  40
  41     # the configure script thinks that Darwin has ___exp10
  42     # but it’s not available on my systems (or hydra apparently)
  43     postConfigure = lib.optionalString stdenv.hostPlatform.isDarwin ''
  44       substituteInPlace config.h \
  45         --replace "#define HAVE___EXP10 1" "#undef HAVE___EXP10"
  46     '';
  47
  48     passthru.tests = {
  49       inherit mu xapian-omega;
  50       inherit (perlPackages) SearchXapian;
  51       python-xapian = python3.pkgs.xapian;
  52     };
  53
  54     meta = with lib; {
  55       description = "Search engine library";
  56       homepage = "https://xapian.org/";
  57       changelog = "https://xapian.org/docs/xapian-core-${version}/NEWS";
  58       license = licenses.gpl2Plus;
  59       maintainers = with maintainers; [ matthiasbeyer ];
  60       platforms = platforms.unix;
  61     };
  62   };
  63 in {
  64   # Don't forget to change the hashes in xapian-omega and
  65   # python3Packages.xapian. They inherit the version from this package, and
  66   # should always be built with the equivalent xapian version.
  67   xapian_1_4 = generic "1.4.26" "sha256-nmp5A4BpZtFs4iC0k3fJyPrWZ8jw/8sjo0QpRiaTY6c=";
  68 }