pkgs/development/python-modules/pyqt6-charts/default.nix

   1 {
   2   lib,
   3   buildPythonPackage,
   4   fetchPypi,
   5   sip,
   6   pyqt-builder,
   7   qt6Packages,
   8   pythonOlder,
   9   pyqt6,
  10   python,
  11   mesa,
  12 }:
  13
  14 buildPythonPackage rec {
  15   pname = "pyqt6-charts";
  16   version = "6.7.0";
  17   format = "pyproject";
  18
  19   disabled = pythonOlder "3.6";
  20
  21   src = fetchPypi {
  22     pname = "PyQt6_Charts";
  23     inherit version;
  24     hash = "sha256-xPfPNpko978DLk4z9xjTuP5m2hdtSVn+MHNalw2G81w=";
  25   };
  26
  27   # fix include path and increase verbosity
  28   postPatch = ''
  29     sed -i \
  30       '/\[tool.sip.project\]/a\
  31       verbose = true\
  32       sip-include-dirs = [\"${pyqt6}/${python.sitePackages}/PyQt6/bindings\"]' \
  33       pyproject.toml
  34   '';
  35
  36   enableParallelBuilding = true;
  37   # HACK: paralellize compilation of make calls within pyqt's setup.py
  38   # pkgs/stdenv/generic/setup.sh doesn't set this for us because
  39   # make gets called by python code and not its build phase
  40   # format=pyproject means the pip-build-hook hook gets used to build this project
  41   # pkgs/development/interpreters/python/hooks/pip-build-hook.sh
  42   # does not use the enableParallelBuilding flag
  43   preBuild = ''
  44     export MAKEFLAGS+="''${enableParallelBuilding:+-j$NIX_BUILD_CORES}"
  45   '';
  46
  47   dontWrapQtApps = true;
  48
  49   nativeBuildInputs = with qt6Packages; [
  50     qtcharts
  51     sip
  52     qmake
  53     pyqt-builder
  54   ];
  55
  56   buildInputs = with qt6Packages; [ qtcharts ];
  57
  58   propagatedBuildInputs = [ pyqt6 ];
  59
  60   dontConfigure = true;
  61
  62   # has no tests
  63   doCheck = false;
  64
  65   pythonImportsCheck = [ "PyQt6.QtCharts" ];
  66
  67   meta = with lib; {
  68     description = "Python bindings for Qt6 QtCharts";
  69     homepage = "https://riverbankcomputing.com/";
  70     license = licenses.gpl3Only;
  71     inherit (mesa.meta) platforms;
  72     maintainers = with maintainers; [ dandellion ];
  73   };
  74 }