pkgs/development/python-modules/soxr/default.nix

   1 {
   2   lib,
   3   apple-sdk_11,
   4   buildPythonPackage,
   5   darwinMinVersionHook,
   6   fetchFromGitHub,
   7   pythonOlder,
   8   stdenv,
   9
  10   # build-system
  11   cmake,
  12   nanobind,
  13   ninja,
  14   scikit-build-core,
  15   setuptools,
  16   setuptools-scm,
  17   typing-extensions,
  18
  19   # native dependencies
  20   libsoxr,
  21
  22   # dependencies
  23   numpy,
  24
  25   # tests
  26   pytestCheckHook,
  27 }:
  28
  29 buildPythonPackage rec {
  30   pname = "soxr";
  31   version = "0.5.0.post1";
  32   pyproject = true;
  33
  34   src = fetchFromGitHub {
  35     owner = "dofuuz";
  36     repo = "python-soxr";
  37     rev = "refs/tags/v${version}";
  38     fetchSubmodules = true;
  39     hash = "sha256-Fpayc+MOpDUCdpoyJaIqSbMzuO0jYb6UN5ARFaxxOHk=";
  40   };
  41
  42   patches = [ ./cmake-nanobind.patch ];
  43
  44   nativeBuildInputs = [
  45     cmake
  46     ninja
  47   ];
  48
  49   dontUseCmakeConfigure = true;
  50
  51   pypaBuildFlags = [
  52     "--config=cmake.define.USE_SYSTEM_LIBSOXR=ON"
  53   ];
  54
  55   build-system =
  56     [
  57       scikit-build-core
  58       nanobind
  59       setuptools
  60       setuptools-scm
  61     ]
  62     ++ lib.optionals (pythonOlder "3.11") [
  63       typing-extensions
  64     ];
  65
  66   buildInputs =
  67     [ libsoxr ]
  68     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  69       # error: aligned deallocation function of type 'void (void *, std::align_val_t) noexcept' is only available on macOS 10.13 or newer
  70       (darwinMinVersionHook "10.13")
  71       apple-sdk_11
  72     ];
  73
  74   dependencies = [ numpy ];
  75
  76   pythonImportsCheck = [ "soxr" ];
  77
  78   nativeCheckInputs = [ pytestCheckHook ];
  79
  80   meta = with lib; {
  81     description = "High quality, one-dimensional sample-rate conversion library";
  82     homepage = "https://github.com/dofuuz/python-soxr/tree/main";
  83     license = licenses.lgpl21Plus;
  84     maintainers = with maintainers; [ hexa ];
  85   };
  86 }