pkgs/development/python-modules/type-infer/default.nix

   1 {
   2   lib,
   3   buildPythonPackage,
   4   pythonOlder,
   5   fetchFromGitHub,
   6   poetry-core,
   7   colorlog,
   8   dataclasses-json,
   9   nltk,
  10   numpy,
  11   pandas,
  12   psutil,
  13   py3langid,
  14   pytestCheckHook,
  15   python-dateutil,
  16   scipy,
  17   toml,
  18   nltk-data,
  19   symlinkJoin,
  20 }:
  21 let
  22   testNltkData = symlinkJoin {
  23     name = "nltk-test-data";
  24     paths = [
  25       nltk-data.punkt
  26       nltk-data.punkt_tab
  27       nltk-data.stopwords
  28     ];
  29   };
  30
  31   version = "0.0.20";
  32   tag = "v${version}";
  33 in
  34 buildPythonPackage rec {
  35   pname = "type-infer";
  36   inherit version;
  37   pyproject = true;
  38
  39   disabled = pythonOlder "3.8";
  40
  41   src = fetchFromGitHub {
  42     owner = "mindsdb";
  43     repo = "type_infer";
  44     inherit tag;
  45     hash = "sha256-2Y+NPwUnQMj0oXoCMfUOG40lqduy9GTcqxfyuFDOkHc=";
  46   };
  47
  48   pythonRelaxDeps = [
  49     "psutil"
  50     "py3langid"
  51   ];
  52
  53   build-system = [ poetry-core ];
  54
  55   dependencies = [
  56     colorlog
  57     dataclasses-json
  58     nltk
  59     numpy
  60     pandas
  61     psutil
  62     py3langid
  63     python-dateutil
  64     scipy
  65     toml
  66   ];
  67
  68   nativeCheckInputs = [
  69     pytestCheckHook
  70   ];
  71
  72   disabledTests = [
  73     # test hangs
  74     "test_1_stack_overflow_survey"
  75   ];
  76
  77   # Package import requires NLTK data to be downloaded
  78   # It is the only way to set NLTK_DATA environment variable,
  79   # so that it is available in pythonImportsCheck
  80   env.NLTK_DATA = testNltkData;
  81   pythonImportsCheck = [ "type_infer" ];
  82
  83   meta = with lib; {
  84     changelog = "https://github.com/mindsdb/type_infer/releases/tag/${tag}";
  85     description = "Automated type inference for Machine Learning pipelines";
  86     homepage = "https://github.com/mindsdb/type_infer";
  87     license = licenses.gpl3Only;
  88     maintainers = with maintainers; [ mbalatsko ];
  89   };
  90 }