pkgs/development/python-modules/ziafont/default.nix

   1 {
   2   lib,
   3   buildPythonPackage,
   4   pythonOlder,
   5   fetchFromGitHub,
   6   setuptools,
   7   pytestCheckHook,
   8   nbval,
   9   fetchurl,
  10 }:
  11 buildPythonPackage rec {
  12   pname = "ziafont";
  13   version = "0.9";
  14   pyproject = true;
  15
  16   disabled = pythonOlder "3.8";
  17
  18   src = fetchFromGitHub {
  19     owner = "cdelker";
  20     repo = "ziafont";
  21     rev = "refs/tags/${version}";
  22     hash = "sha256-S7IDL3ItP14/GrCUtSTT+JWuqRAY/Po0Kerq8mggDdg=";
  23   };
  24
  25   build-system = [ setuptools ];
  26
  27   nativeCheckInputs = [
  28     pytestCheckHook
  29     nbval
  30   ];
  31
  32   preCheck =
  33     let
  34       # The test notebooks try to download font files, unless they already exist in the test directory,
  35       # so we prepare them in advance.
  36       checkFonts = lib.map fetchurl (import ./checkfonts.nix);
  37       copyFontCmd = font: "cp ${font} test/${lib.last (lib.splitString "/" font.url)}\n";
  38     in
  39     lib.concatMapStrings copyFontCmd checkFonts;
  40
  41   pytestFlagsArray = [ "--nbval-lax" ];
  42
  43   pythonImportsCheck = [ "ziafont" ];
  44
  45   meta = {
  46     description = "Convert TTF/OTF font glyphs to SVG paths";
  47     homepage = "https://ziafont.readthedocs.io/en/latest/";
  48     changelog = "https://github.com/cdelker/ziafont/blob/main/CHANGES.md";
  49     license = lib.licenses.mit;
  50     maintainers = [ lib.maintainers.sfrijters ];
  51   };
  52 }