pkgs/misc/uboot/default.nix

   1 { stdenv
   2 , lib
   3 , bc
   4 , bison
   5 , dtc
   6 , fetchFromGitHub
   7 , fetchpatch
   8 , fetchurl
   9 , flex
  10 , gnutls
  11 , installShellFiles
  12 , libuuid
  13 , meson-tools
  14 , ncurses
  15 , openssl
  16 , rkbin
  17 , swig
  18 , which
  19 , python3
  20 , perl
  21 , armTrustedFirmwareAllwinner
  22 , armTrustedFirmwareAllwinnerH6
  23 , armTrustedFirmwareAllwinnerH616
  24 , armTrustedFirmwareRK3328
  25 , armTrustedFirmwareRK3399
  26 , armTrustedFirmwareRK3588
  27 , armTrustedFirmwareS905
  28 , buildPackages
  29 }:
  30
  31 let
  32   defaultVersion = "2024.10";
  33   defaultSrc = fetchurl {
  34     url = "https://ftp.denx.de/pub/u-boot/u-boot-${defaultVersion}.tar.bz2";
  35     hash = "sha256-so2vSsF+QxVjYweL9RApdYQTf231D87ZsS3zT2GpL7A=";
  36   };
  37
  38   # Dependencies for the tools need to be included as either native or cross,
  39   # depending on which we're building
  40   toolsDeps = [
  41     ncurses # tools/kwboot
  42     libuuid # tools/mkeficapsule
  43     gnutls # tools/mkeficapsule
  44     openssl # tools/mkimage
  45   ];
  46
  47   buildUBoot = lib.makeOverridable ({
  48     version ? null
  49   , src ? null
  50   , filesToInstall
  51   , pythonScriptsToInstall ? { }
  52   , installDir ? "$out"
  53   , defconfig
  54   , extraConfig ? ""
  55   , extraPatches ? []
  56   , extraMakeFlags ? []
  57   , extraMeta ? {}
  58   , crossTools ? false
  59   , ... } @ args: stdenv.mkDerivation ({
  60     pname = "uboot-${defconfig}";
  61
  62     version = if src == null then defaultVersion else version;
  63
  64     src = if src == null then defaultSrc else src;
  65
  66     patches = [
  67       ./0001-configs-rpi-allow-for-bigger-kernels.patch
  68     ] ++ extraPatches;
  69
  70     postPatch = ''
  71       ${lib.concatMapStrings (script: ''
  72         substituteInPlace ${script} \
  73         --replace "#!/usr/bin/env python3" "#!${pythonScriptsToInstall.${script}}/bin/python3"
  74       '') (builtins.attrNames pythonScriptsToInstall)}
  75       patchShebangs tools
  76       patchShebangs scripts
  77     '';
  78
  79     nativeBuildInputs = [
  80       ncurses # tools/kwboot
  81       bc
  82       bison
  83       flex
  84       installShellFiles
  85       (buildPackages.python3.withPackages (p: [
  86         p.libfdt
  87         p.setuptools # for pkg_resources
  88         p.pyelftools
  89       ]))
  90       swig
  91       which # for scripts/dtc-version.sh
  92       perl # for oid build (secureboot)
  93     ] ++ lib.optionals (!crossTools) toolsDeps;
  94     depsBuildBuild = [ buildPackages.stdenv.cc ];
  95     buildInputs = lib.optionals crossTools toolsDeps;
  96
  97     hardeningDisable = [ "all" ];
  98
  99     enableParallelBuilding = true;
 100
 101     makeFlags = [
 102       "DTC=${lib.getExe buildPackages.dtc}"
 103       "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
 104     ] ++ extraMakeFlags;
 105
 106     passAsFile = [ "extraConfig" ];
 107
 108     configurePhase = ''
 109       runHook preConfigure
 110
 111       make ${defconfig}
 112
 113       cat $extraConfigPath >> .config
 114
 115       runHook postConfigure
 116     '';
 117
 118     installPhase = ''
 119       runHook preInstall
 120
 121       mkdir -p ${installDir}
 122       cp ${lib.concatStringsSep " " (filesToInstall ++ builtins.attrNames pythonScriptsToInstall)} ${installDir}
 123
 124       mkdir -p "$out/nix-support"
 125       ${lib.concatMapStrings (file: ''
 126         echo "file binary-dist ${installDir}/${builtins.baseNameOf file}" >> "$out/nix-support/hydra-build-products"
 127       '') (filesToInstall ++ builtins.attrNames pythonScriptsToInstall)}
 128
 129       runHook postInstall
 130     '';
 131
 132     dontStrip = true;
 133
 134     meta = with lib; {
 135       homepage = "https://www.denx.de/wiki/U-Boot/";
 136       description = "Boot loader for embedded systems";
 137       license = licenses.gpl2Plus;
 138       maintainers = with maintainers; [ bartsch dezgeg lopsided98 ];
 139     } // extraMeta;
 140   } // removeAttrs args [ "extraMeta" "pythonScriptsToInstall" ]));
 141 in {
 142   inherit buildUBoot;
 143
 144   ubootTools = buildUBoot {
 145     defconfig = "tools-only_defconfig";
 146     installDir = "$out/bin";
 147     hardeningDisable = [];
 148     dontStrip = false;
 149     extraMeta.platforms = lib.platforms.linux;
 150
 151     crossTools = true;
 152     extraMakeFlags = [ "HOST_TOOLS_ALL=y" "NO_SDL=1" "cross_tools" ];
 153
 154     outputs = [ "out" "man" ];
 155
 156     postInstall = ''
 157       installManPage doc/*.1
 158     '';
 159     filesToInstall = [
 160       "tools/dumpimage"
 161       "tools/fdtgrep"
 162       "tools/kwboot"
 163       "tools/mkenvimage"
 164       "tools/mkimage"
 165     ];
 166
 167     pythonScriptsToInstall = {
 168       "tools/efivar.py" = (python3.withPackages (ps: [ ps.pyopenssl ]));
 169     };
 170   };
 171
 172   ubootA20OlinuxinoLime = buildUBoot {
 173     defconfig = "A20-OLinuXino-Lime_defconfig";
 174     extraMeta.platforms = ["armv7l-linux"];
 175     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 176   };
 177
 178   ubootA20OlinuxinoLime2EMMC = buildUBoot {
 179     defconfig = "A20-OLinuXino-Lime2-eMMC_defconfig";
 180     extraMeta.platforms = ["armv7l-linux"];
 181     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 182   };
 183
 184   ubootAmx335xEVM = buildUBoot {
 185     defconfig = "am335x_evm_defconfig";
 186     extraMeta.platforms = ["armv7l-linux"];
 187     filesToInstall = ["MLO" "u-boot.img"];
 188   };
 189
 190   ubootBananaPi = buildUBoot {
 191     defconfig = "Bananapi_defconfig";
 192     extraMeta.platforms = ["armv7l-linux"];
 193     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 194   };
 195
 196   ubootBananaPim3 = buildUBoot {
 197     defconfig = "Sinovoip_BPI_M3_defconfig";
 198     extraMeta.platforms = ["armv7l-linux"];
 199     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 200   };
 201
 202   ubootBananaPim64 = buildUBoot {
 203     defconfig = "bananapi_m64_defconfig";
 204     extraMeta.platforms = ["aarch64-linux"];
 205     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 206     SCP = "/dev/null";
 207     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 208   };
 209
 210   # http://git.denx.de/?p=u-boot.git;a=blob;f=board/solidrun/clearfog/README;hb=refs/heads/master
 211   ubootClearfog = buildUBoot {
 212     defconfig = "clearfog_defconfig";
 213     extraMeta.platforms = ["armv7l-linux"];
 214     filesToInstall = ["u-boot-with-spl.kwb"];
 215   };
 216
 217   ubootCM3588NAS = buildUBoot {
 218     defconfig = "cm3588-nas-rk3588_defconfig";
 219     extraMeta.platforms = [ "aarch64-linux" ];
 220     BL31 = "${armTrustedFirmwareRK3588}/bl31.elf";
 221     ROCKCHIP_TPL = rkbin.TPL_RK3588;
 222     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" ];
 223   };
 224
 225   ubootCubieboard2 = buildUBoot {
 226     defconfig = "Cubieboard2_defconfig";
 227     extraMeta.platforms = ["armv7l-linux"];
 228     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 229   };
 230
 231   ubootGuruplug = buildUBoot {
 232     defconfig = "guruplug_defconfig";
 233     extraMeta.platforms = ["armv5tel-linux"];
 234     filesToInstall = ["u-boot.bin"];
 235   };
 236
 237   ubootJetsonTK1 = buildUBoot {
 238     defconfig = "jetson-tk1_defconfig";
 239     extraMeta.platforms = ["armv7l-linux"];
 240     filesToInstall = ["u-boot" "u-boot.dtb" "u-boot-dtb-tegra.bin" "u-boot-nodtb-tegra.bin"];
 241     # tegra-uboot-flasher expects this exact directory layout, sigh...
 242     postInstall = ''
 243       mkdir -p $out/spl
 244       cp spl/u-boot-spl $out/spl/
 245     '';
 246   };
 247
 248   # Flashing instructions:
 249   # dd if=u-boot.gxl.sd.bin of=<sdcard> conv=fsync,notrunc bs=512 skip=1 seek=1
 250   # dd if=u-boot.gxl.sd.bin of=<sdcard> conv=fsync,notrunc bs=1 count=444
 251   ubootLibreTechCC = let
 252     firmwareImagePkg = fetchFromGitHub {
 253       owner = "LibreELEC";
 254       repo = "amlogic-boot-fip";
 255       rev = "4369a138ca24c5ab932b8cbd1af4504570b709df";
 256       sha256 = "sha256-mGRUwdh3nW4gBwWIYHJGjzkezHxABwcwk/1gVRis7Tc=";
 257       meta.license = lib.licenses.unfreeRedistributableFirmware;
 258     };
 259   in
 260   assert stdenv.buildPlatform.system == "x86_64-linux"; # aml_encrypt_gxl is a x86_64 binary
 261   buildUBoot {
 262     defconfig = "libretech-cc_defconfig";
 263     extraMeta.platforms = ["aarch64-linux"];
 264     filesToInstall = ["u-boot.bin"];
 265     postBuild = ''
 266       # Copy binary files & tools from LibreELEC/amlogic-boot-fip, and u-boot build to working dir
 267       mkdir $out tmp
 268       cp ${firmwareImagePkg}/lepotato/{acs.bin,bl2.bin,bl21.bin,bl30.bin,bl301.bin,bl31.img} \
 269          ${firmwareImagePkg}/lepotato/{acs_tool.py,aml_encrypt_gxl,blx_fix.sh} \
 270          u-boot.bin tmp/
 271       cd tmp
 272       python3 acs_tool.py bl2.bin bl2_acs.bin acs.bin 0
 273
 274       bash -e blx_fix.sh bl2_acs.bin zero bl2_zero.bin bl21.bin bl21_zero.bin bl2_new.bin bl2
 275       [ -f zero ] && rm zero
 276
 277       bash -e blx_fix.sh bl30.bin zero bl30_zero.bin bl301.bin bl301_zero.bin bl30_new.bin bl30
 278       [ -f zero ] && rm zero
 279
 280       ./aml_encrypt_gxl --bl2sig --input bl2_new.bin --output bl2.n.bin.sig
 281       ./aml_encrypt_gxl --bl3enc --input bl30_new.bin --output bl30_new.bin.enc
 282       ./aml_encrypt_gxl --bl3enc --input bl31.img --output bl31.img.enc
 283       ./aml_encrypt_gxl --bl3enc --input u-boot.bin --output bl33.bin.enc
 284       ./aml_encrypt_gxl --bootmk --output $out/u-boot.gxl \
 285         --bl2 bl2.n.bin.sig --bl30 bl30_new.bin.enc --bl31 bl31.img.enc --bl33 bl33.bin.enc
 286     '';
 287   };
 288
 289   ubootNanoPCT4 = buildUBoot rec {
 290     rkbin = fetchFromGitHub {
 291       owner = "armbian";
 292       repo = "rkbin";
 293       rev = "3bd0321cae5ef881a6005fb470009ad5a5d1462d";
 294       sha256 = "09r4dzxsbs3pff4sh70qnyp30s3rc7pkc46v1m3152s7jqjasp31";
 295     };
 296
 297     defconfig = "nanopc-t4-rk3399_defconfig";
 298
 299     extraMeta = {
 300       platforms = ["aarch64-linux"];
 301       license = lib.licenses.unfreeRedistributableFirmware;
 302     };
 303     BL31="${armTrustedFirmwareRK3399}/bl31.elf";
 304     filesToInstall = ["u-boot.itb" "idbloader.img"];
 305     postBuild = ''
 306       ./tools/mkimage -n rk3399 -T rksd -d ${rkbin}/rk33/rk3399_ddr_800MHz_v1.24.bin idbloader.img
 307       cat ${rkbin}/rk33/rk3399_miniloader_v1.19.bin >> idbloader.img
 308     '';
 309   };
 310
 311   ubootNanoPCT6 = buildUBoot {
 312     defconfig = "nanopc-t6-rk3588_defconfig";
 313     extraMeta.platforms = ["aarch64-linux"];
 314     BL31 = "${armTrustedFirmwareRK3588}/bl31.elf";
 315     ROCKCHIP_TPL = rkbin.TPL_RK3588;
 316     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" "u-boot-rockchip-spi.bin" ];
 317   };
 318
 319   ubootNovena = buildUBoot {
 320     defconfig = "novena_defconfig";
 321     extraMeta.platforms = ["armv7l-linux"];
 322     filesToInstall = ["u-boot-dtb.img" "SPL"];
 323   };
 324
 325   # Flashing instructions:
 326   # dd if=bl1.bin.hardkernel of=<device> conv=fsync bs=1 count=442
 327   # dd if=bl1.bin.hardkernel of=<device> conv=fsync bs=512 skip=1 seek=1
 328   # dd if=u-boot.gxbb of=<device> conv=fsync bs=512 seek=97
 329   ubootOdroidC2 = let
 330     firmwareBlobs = fetchFromGitHub {
 331       owner = "armbian";
 332       repo = "odroidc2-blobs";
 333       rev = "47c5aac4bcac6f067cebe76e41fb9924d45b429c";
 334       sha256 = "1ns0a130yxnxysia8c3q2fgyjp9k0nkr689dxk88qh2vnibgchnp";
 335       meta.license = lib.licenses.unfreeRedistributableFirmware;
 336     };
 337   in buildUBoot {
 338     defconfig = "odroid-c2_defconfig";
 339     extraMeta.platforms = ["aarch64-linux"];
 340     filesToInstall = ["u-boot.bin" "u-boot.gxbb" "${firmwareBlobs}/bl1.bin.hardkernel"];
 341     postBuild = ''
 342       # BL301 image needs at least 64 bytes of padding after it to place
 343       # signing headers (with amlbootsig)
 344       truncate -s 64 bl301.padding.bin
 345       cat '${firmwareBlobs}/gxb/bl301.bin' bl301.padding.bin > bl301.padded.bin
 346       # The downstream fip_create tool adds a custom TOC entry with UUID
 347       # AABBCCDD-ABCD-EFEF-ABCD-12345678ABCD for the BL301 image. It turns out
 348       # that the firmware blob does not actually care about UUIDs, only the
 349       # order the images appear in the file. Because fiptool does not know
 350       # about the BL301 UUID, we would have to use the --blob option, which adds
 351       # the image to the end of the file, causing the boot to fail. Instead, we
 352       # take advantage of the fact that UUIDs are ignored and just put the
 353       # images in the right order with the wrong UUIDs. In the command below,
 354       # --tb-fw is really --scp-fw and --scp-fw is the BL301 image.
 355       #
 356       # See https://github.com/afaerber/meson-tools/issues/3 for more
 357       # information.
 358       '${buildPackages.armTrustedFirmwareTools}/bin/fiptool' create \
 359         --align 0x4000 \
 360         --tb-fw '${firmwareBlobs}/gxb/bl30.bin' \
 361         --scp-fw bl301.padded.bin \
 362         --soc-fw '${armTrustedFirmwareS905}/bl31.bin' \
 363         --nt-fw u-boot.bin \
 364         fip.bin
 365       cat '${firmwareBlobs}/gxb/bl2.package' fip.bin > boot_new.bin
 366       '${buildPackages.meson-tools}/bin/amlbootsig' boot_new.bin u-boot.img
 367       dd if=u-boot.img of=u-boot.gxbb bs=512 skip=96
 368     '';
 369   };
 370
 371   ubootOdroidXU3 = buildUBoot {
 372     defconfig = "odroid-xu3_defconfig";
 373     extraMeta.platforms = ["armv7l-linux"];
 374     filesToInstall = ["u-boot-dtb.bin"];
 375   };
 376
 377   ubootOlimexA64Olinuxino = buildUBoot {
 378     defconfig = "a64-olinuxino-emmc_defconfig";
 379     extraMeta.platforms = ["aarch64-linux"];
 380     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 381     SCP = "/dev/null";
 382     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 383   };
 384
 385   ubootOlimexA64Teres1 = buildUBoot {
 386     defconfig = "teres_i_defconfig";
 387     extraMeta.platforms = ["aarch64-linux"];
 388     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 389     # Using /dev/null here is upstream-specified way that disables the inclusion of crust-firmware as it's not yet packaged and without which the build will fail -- https://docs.u-boot.org/en/latest/board/allwinner/sunxi.html#building-the-crust-management-processor-firmware
 390     SCP = "/dev/null";
 391     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 392   };
 393
 394   ubootOrangePi5 = buildUBoot {
 395     defconfig = "orangepi-5-rk3588s_defconfig";
 396     extraMeta.platforms = ["aarch64-linux"];
 397     BL31 = "${armTrustedFirmwareRK3588}/bl31.elf";
 398     ROCKCHIP_TPL = rkbin.TPL_RK3588;
 399     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" "u-boot-rockchip-spi.bin" ];
 400   };
 401
 402   ubootOrangePi5Plus = buildUBoot {
 403     defconfig = "orangepi-5-plus-rk3588_defconfig";
 404     extraMeta.platforms = ["aarch64-linux"];
 405     BL31 = "${armTrustedFirmwareRK3588}/bl31.elf";
 406     ROCKCHIP_TPL = rkbin.TPL_RK3588;
 407     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" "u-boot-rockchip-spi.bin" ];
 408   };
 409
 410   ubootOrangePiPc = buildUBoot {
 411     defconfig = "orangepi_pc_defconfig";
 412     extraMeta.platforms = ["armv7l-linux"];
 413     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 414   };
 415
 416   ubootOrangePiZeroPlus2H5 = buildUBoot {
 417     defconfig = "orangepi_zero_plus2_defconfig";
 418     extraMeta.platforms = ["aarch64-linux"];
 419     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 420     SCP = "/dev/null";
 421     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 422   };
 423
 424   ubootOrangePiZero = buildUBoot {
 425     defconfig = "orangepi_zero_defconfig";
 426     extraMeta.platforms = ["armv7l-linux"];
 427     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 428   };
 429
 430   ubootOrangePiZero2 = buildUBoot {
 431     defconfig = "orangepi_zero2_defconfig";
 432     extraMeta.platforms = ["aarch64-linux"];
 433     BL31 = "${armTrustedFirmwareAllwinnerH616}/bl31.bin";
 434     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 435   };
 436
 437   ubootOrangePiZero3 = buildUBoot {
 438     defconfig = "orangepi_zero3_defconfig";
 439     extraMeta.platforms = ["aarch64-linux"];
 440     # According to https://linux-sunxi.org/H616 the H618 "is a minor update with a larger (1MB) L2 cache" (compared to the H616)
 441     # but "does require extra support in U-Boot, TF-A and sunxi-fel. Support for that has been merged in mainline releases."
 442     # But no extra support seems to be in TF-A.
 443     BL31 = "${armTrustedFirmwareAllwinnerH616}/bl31.bin";
 444     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 445   };
 446
 447   ubootOrangePi3 = buildUBoot {
 448     defconfig = "orangepi_3_defconfig";
 449     extraMeta.platforms = ["aarch64-linux"];
 450     BL31 = "${armTrustedFirmwareAllwinnerH6}/bl31.bin";
 451     SCP = "/dev/null";
 452     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 453   };
 454
 455   ubootOrangePi3B = buildUBoot {
 456     defconfig = "orangepi-3b-rk3566_defconfig";
 457     extraMeta.platforms = ["aarch64-linux"];
 458     ROCKCHIP_TPL = rkbin.TPL_RK3568;
 459     BL31 = rkbin.BL31_RK3568;
 460     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" "u-boot-rockchip-spi.bin" ];
 461   };
 462
 463   ubootPcduino3Nano = buildUBoot {
 464     defconfig = "Linksprite_pcDuino3_Nano_defconfig";
 465     extraMeta.platforms = ["armv7l-linux"];
 466     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 467   };
 468
 469   ubootPine64 = buildUBoot {
 470     defconfig = "pine64_plus_defconfig";
 471     extraMeta.platforms = ["aarch64-linux"];
 472     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 473     SCP = "/dev/null";
 474     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 475   };
 476
 477   ubootPine64LTS = buildUBoot {
 478     defconfig = "pine64-lts_defconfig";
 479     extraMeta.platforms = ["aarch64-linux"];
 480     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 481     SCP = "/dev/null";
 482     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 483   };
 484
 485   ubootPinebook = buildUBoot {
 486     defconfig = "pinebook_defconfig";
 487     extraMeta.platforms = ["aarch64-linux"];
 488     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 489     SCP = "/dev/null";
 490     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 491   };
 492
 493   ubootPinebookPro = buildUBoot {
 494     defconfig = "pinebook-pro-rk3399_defconfig";
 495     extraMeta.platforms = ["aarch64-linux"];
 496     BL31 = "${armTrustedFirmwareRK3399}/bl31.elf";
 497     filesToInstall = [ "u-boot.itb" "idbloader.img"];
 498   };
 499
 500   ubootQemuAarch64 = buildUBoot {
 501     defconfig = "qemu_arm64_defconfig";
 502     extraMeta.platforms = ["aarch64-linux"];
 503     filesToInstall = ["u-boot.bin"];
 504   };
 505
 506   ubootQemuArm = buildUBoot {
 507     defconfig = "qemu_arm_defconfig";
 508     extraMeta.platforms = ["armv7l-linux"];
 509     filesToInstall = ["u-boot.bin"];
 510   };
 511
 512   ubootQemuRiscv64Smode = buildUBoot {
 513     defconfig = "qemu-riscv64_smode_defconfig";
 514     extraMeta.platforms = ["riscv64-linux"];
 515     filesToInstall = ["u-boot.bin"];
 516   };
 517
 518   ubootQemuX86 = buildUBoot {
 519     defconfig = "qemu-x86_defconfig";
 520     extraConfig = ''
 521       CONFIG_USB_UHCI_HCD=y
 522       CONFIG_USB_EHCI_HCD=y
 523       CONFIG_USB_EHCI_GENERIC=y
 524       CONFIG_USB_XHCI_HCD=y
 525     '';
 526     extraMeta.platforms = [ "i686-linux" "x86_64-linux" ];
 527     filesToInstall = [ "u-boot.rom" ];
 528   };
 529
 530   ubootRaspberryPi = buildUBoot {
 531     defconfig = "rpi_defconfig";
 532     extraMeta.platforms = ["armv6l-linux"];
 533     filesToInstall = ["u-boot.bin"];
 534   };
 535
 536   ubootRaspberryPi2 = buildUBoot {
 537     defconfig = "rpi_2_defconfig";
 538     extraMeta.platforms = ["armv7l-linux"];
 539     filesToInstall = ["u-boot.bin"];
 540   };
 541
 542   ubootRaspberryPi3_32bit = buildUBoot {
 543     defconfig = "rpi_3_32b_defconfig";
 544     extraMeta.platforms = ["armv7l-linux"];
 545     filesToInstall = ["u-boot.bin"];
 546   };
 547
 548   ubootRaspberryPi3_64bit = buildUBoot {
 549     defconfig = "rpi_3_defconfig";
 550     extraMeta.platforms = ["aarch64-linux"];
 551     filesToInstall = ["u-boot.bin"];
 552   };
 553
 554   ubootRaspberryPi4_32bit = buildUBoot {
 555     defconfig = "rpi_4_32b_defconfig";
 556     extraMeta.platforms = ["armv7l-linux"];
 557     filesToInstall = ["u-boot.bin"];
 558   };
 559
 560   ubootRaspberryPi4_64bit = buildUBoot {
 561     defconfig = "rpi_4_defconfig";
 562     extraMeta.platforms = ["aarch64-linux"];
 563     filesToInstall = ["u-boot.bin"];
 564   };
 565
 566   ubootRaspberryPiZero = buildUBoot {
 567     defconfig = "rpi_0_w_defconfig";
 568     extraMeta.platforms = ["armv6l-linux"];
 569     filesToInstall = ["u-boot.bin"];
 570   };
 571
 572   ubootRock4CPlus = buildUBoot {
 573     defconfig = "rock-4c-plus-rk3399_defconfig";
 574     extraMeta.platforms = [ "aarch64-linux" ];
 575     BL31 = "${armTrustedFirmwareRK3399}/bl31.elf";
 576     filesToInstall = [ "u-boot.itb" "idbloader.img" ];
 577   };
 578
 579   ubootRock5ModelB = buildUBoot {
 580     defconfig = "rock5b-rk3588_defconfig";
 581     extraMeta.platforms = ["aarch64-linux"];
 582     BL31 = "${armTrustedFirmwareRK3588}/bl31.elf";
 583     ROCKCHIP_TPL = rkbin.TPL_RK3588;
 584     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" "u-boot-rockchip-spi.bin" ];
 585   };
 586
 587   ubootRock64 = buildUBoot {
 588     defconfig = "rock64-rk3328_defconfig";
 589     extraMeta.platforms = [ "aarch64-linux" ];
 590     BL31="${armTrustedFirmwareRK3328}/bl31.elf";
 591     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" ];
 592   };
 593
 594   # A special build with much lower memory frequency (666 vs 1600 MT/s) which
 595   # makes ROCK64 V2 boards stable. This is necessary because the DDR3 routing
 596   # on that revision is marginal and not uncoditionally stable at the specified
 597   # frequency. If your ROCK64 is unstable you can try this u-boot variant to
 598   # see if it works better for you. The only disadvantage is lowered memory
 599   # bandwidth.
 600   ubootRock64v2 = buildUBoot {
 601     prePatch = ''
 602       substituteInPlace arch/arm/dts/rk3328-rock64-u-boot.dtsi \
 603         --replace rk3328-sdram-lpddr3-1600.dtsi rk3328-sdram-lpddr3-666.dtsi
 604     '';
 605     defconfig = "rock64-rk3328_defconfig";
 606     extraMeta.platforms = [ "aarch64-linux" ];
 607     BL31="${armTrustedFirmwareRK3328}/bl31.elf";
 608     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" ];
 609   };
 610
 611   ubootRockPro64 = buildUBoot {
 612     extraPatches = [
 613       # https://patchwork.ozlabs.org/project/uboot/list/?series=237654&archive=both&state=*
 614       (fetchpatch {
 615         url = "https://patchwork.ozlabs.org/series/237654/mbox/";
 616         sha256 = "0aiw9zk8w4msd3v8nndhkspjify0yq6a5f0zdy6mhzs0ilq896c3";
 617       })
 618     ];
 619     defconfig = "rockpro64-rk3399_defconfig";
 620     extraMeta.platforms = ["aarch64-linux"];
 621     BL31="${armTrustedFirmwareRK3399}/bl31.elf";
 622     filesToInstall = [ "u-boot.itb" "idbloader.img"];
 623   };
 624
 625   ubootROCPCRK3399 = buildUBoot {
 626     defconfig = "roc-pc-rk3399_defconfig";
 627     extraMeta.platforms = ["aarch64-linux"];
 628     filesToInstall = [ "spl/u-boot-spl.bin" "u-boot.itb" "idbloader.img"];
 629     BL31 = "${armTrustedFirmwareRK3399}/bl31.elf";
 630   };
 631
 632   ubootSheevaplug = buildUBoot {
 633     defconfig = "sheevaplug_defconfig";
 634     extraMeta.platforms = ["armv5tel-linux"];
 635     filesToInstall = ["u-boot.kwb"];
 636   };
 637
 638   ubootSopine = buildUBoot {
 639     defconfig = "sopine_baseboard_defconfig";
 640     extraMeta.platforms = ["aarch64-linux"];
 641     BL31 = "${armTrustedFirmwareAllwinner}/bl31.bin";
 642     SCP = "/dev/null";
 643     filesToInstall = ["u-boot-sunxi-with-spl.bin"];
 644   };
 645
 646   ubootTuringRK1 = buildUBoot {
 647     defconfig = "turing-rk1-rk3588_defconfig";
 648     extraMeta.platforms = [ "aarch64-linux" ];
 649     BL31 = "${armTrustedFirmwareRK3588}/bl31.elf";
 650     ROCKCHIP_TPL = rkbin.TPL_RK3588;
 651     filesToInstall = [ "u-boot.itb" "idbloader.img" "u-boot-rockchip.bin" ];
 652   };
 653
 654   ubootUtilite = buildUBoot {
 655     defconfig = "cm_fx6_defconfig";
 656     extraMeta.platforms = ["armv7l-linux"];
 657     filesToInstall = ["u-boot-with-nand-spl.imx"];
 658     buildFlags = [ "u-boot-with-nand-spl.imx" ];
 659     extraConfig = ''
 660       CONFIG_CMD_SETEXPR=y
 661     '';
 662     # sata init; load sata 0 $loadaddr u-boot-with-nand-spl.imx
 663     # sf probe; sf update $loadaddr 0 80000
 664   };
 665
 666   ubootWandboard = buildUBoot {
 667     defconfig = "wandboard_defconfig";
 668     extraMeta.platforms = ["armv7l-linux"];
 669     filesToInstall = ["u-boot.img" "SPL"];
 670   };
 671
 672   ubootRockPi4 = buildUBoot {
 673     defconfig = "rock-pi-4-rk3399_defconfig";
 674     extraMeta.platforms = ["aarch64-linux"];
 675     BL31 = "${armTrustedFirmwareRK3399}/bl31.elf";
 676     filesToInstall = [ "u-boot.itb" "idbloader.img"];
 677   };
 678 }