pkgs/os-specific/linux/decklink/default.nix

   1 {
   2   stdenv,
   3   lib,
   4   blackmagic-desktop-video,
   5   kernel,
   6 }:
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "decklink";
   9
  10   # the download is a horrible curl mess. we reuse it between the kernel module
  11   # and desktop service, since the version of the two have to match anyways.
  12   # See pkgs/by-name/bl/blackmagic-desktop-video/package.nix for more.
  13   inherit (blackmagic-desktop-video) src version;
  14
  15   KERNELDIR = "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build";
  16   INSTALL_MOD_PATH = placeholder "out";
  17
  18   nativeBuildInputs = kernel.moduleBuildDependencies;
  19
  20   postUnpack =
  21     let
  22       arch = stdenv.hostPlatform.uname.processor;
  23     in
  24     ''
  25       tar xf Blackmagic_Desktop_Video_Linux_${lib.head (lib.splitString "a" finalAttrs.version)}/other/${arch}/desktopvideo-${finalAttrs.version}-${arch}.tar.gz
  26       moduleRoot=$NIX_BUILD_TOP/desktopvideo-${finalAttrs.version}-${stdenv.hostPlatform.uname.processor}/usr/src
  27       sourceRoot=$moduleRoot
  28     '';
  29
  30   buildPhase = ''
  31     runHook preBuild
  32     make -C $moduleRoot/blackmagic-${finalAttrs.version} -j$NIX_BUILD_CORES
  33     make -C $moduleRoot/blackmagic-io-${finalAttrs.version} -j$NIX_BUILD_CORES
  34     runHook postBuild
  35   '';
  36
  37   installPhase = ''
  38     runHook preInstall
  39     make -C $KERNELDIR M=$moduleRoot/blackmagic-${finalAttrs.version} modules_install
  40     make -C $KERNELDIR M=$moduleRoot/blackmagic-io-${finalAttrs.version} modules_install
  41     runHook postInstall
  42   '';
  43
  44   meta = with lib; {
  45     homepage = "https://www.blackmagicdesign.com/support/family/capture-and-playback";
  46     maintainers = [ maintainers.naxdy ];
  47     license = licenses.unfree;
  48     description = "Kernel module for the Blackmagic Design Decklink cards";
  49     sourceProvenance = with lib.sourceTypes; [ binaryFirmware ];
  50     platforms = platforms.linux;
  51   };
  52 })