pkgs/os-specific/linux/ipu6-drivers/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , ivsc-driver
   5 , kernel
   6 }:
   7
   8 stdenv.mkDerivation rec {
   9   pname = "ipu6-drivers";
  10   version = "unstable-2024-11-19";
  11
  12   src = fetchFromGitHub {
  13     owner = "intel";
  14     repo = "ipu6-drivers";
  15     rev = "0ad4988248d7e9382498a0b47fc78bb990b29a58";
  16     hash = "sha256-UFvwuoAzwk1k4YiUK+4EeMKeTx9nVvBgBN5JKAfqZkQ=";
  17   };
  18
  19   patches = [
  20     "${src}/patches/0001-v6.10-IPU6-headers-used-by-PSYS.patch"
  21   ];
  22
  23   postPatch = ''
  24     cp --no-preserve=mode --recursive --verbose \
  25       ${ivsc-driver.src}/backport-include \
  26       ${ivsc-driver.src}/drivers \
  27       ${ivsc-driver.src}/include \
  28       .
  29   '';
  30
  31   nativeBuildInputs = kernel.moduleBuildDependencies;
  32
  33   makeFlags = kernel.makeFlags ++ [
  34     "KERNELRELEASE=${kernel.modDirVersion}"
  35     "KERNEL_SRC=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
  36   ];
  37
  38   enableParallelBuilding = true;
  39
  40   preInstall = ''
  41     sed -i -e "s,INSTALL_MOD_DIR=,INSTALL_MOD_PATH=$out INSTALL_MOD_DIR=," Makefile
  42   '';
  43
  44   installTargets = [
  45     "modules_install"
  46   ];
  47
  48   meta = {
  49     homepage = "https://github.com/intel/ipu6-drivers";
  50     description = "IPU6 kernel driver";
  51     license = lib.licenses.gpl2Only;
  52     maintainers = [ ];
  53     platforms = [ "x86_64-linux" ];
  54     # requires 6.10
  55     broken = kernel.kernelOlder "6.10";
  56   };
  57 }