pkgs/os-specific/linux/nvidia-x11/generic.nix

   1 { version
   2 , url ? null
   3 , sha256_32bit ? null
   4 , sha256_64bit
   5 , sha256_aarch64 ? null
   6 , openSha256 ? null
   7 , settingsSha256 ? null
   8 , settingsVersion ? version
   9 , persistencedSha256 ? null
  10 , persistencedVersion ? version
  11 , fabricmanagerSha256 ? null
  12 , fabricmanagerVersion ? version
  13 , useGLVND ? true
  14 , useProfiles ? true
  15 , preferGtk2 ? false
  16 , settings32Bit ? false
  17 , useSettings ? true
  18 , usePersistenced ? true
  19 , useFabricmanager ? false
  20 , ibtSupport ? false
  21
  22 , prePatch ? null
  23 , postPatch ? null
  24 , patchFlags ? null
  25 , patches ? [ ]
  26 , patchesOpen ? [ ]
  27 , preInstall ? null
  28 , postInstall ? null
  29 , broken ? false
  30 , brokenOpen ? broken
  31 }@args:
  32
  33 { lib
  34 , stdenv
  35 , runCommandLocal
  36 , patchutils
  37 , callPackage
  38 , pkgs
  39 , pkgsi686Linux
  40 , fetchurl
  41 , fetchzip
  42 , kernel ? null
  43 , perl
  44 , nukeReferences
  45 , which
  46 , libarchive
  47 , jq
  48 , # Whether to build the libraries only (i.e. not the kernel module or
  49   # nvidia-settings).  Used to support 32-bit binaries on 64-bit
  50   # Linux.
  51   libsOnly ? false
  52 , # don't include the bundled 32-bit libraries on 64-bit platforms,
  53   # even if it’s in downloaded binary
  54   disable32Bit ? stdenv.hostPlatform.system == "aarch64-linux"
  55   # 32 bit libs only version of this package
  56 , lib32 ? null
  57   # Whether to extract the GSP firmware, datacenter drivers needs to extract the
  58   # firmware
  59 , firmware ? openSha256 != null || useFabricmanager
  60   # Whether the user accepts the NVIDIA Software License
  61 , config
  62 , acceptLicense ? config.nvidia.acceptLicense or false
  63 }:
  64
  65 assert !libsOnly -> kernel != null;
  66 assert lib.versionOlder version "391" -> sha256_32bit != null;
  67 assert useSettings -> settingsSha256 != null;
  68 assert usePersistenced -> persistencedSha256 != null;
  69 assert useFabricmanager -> fabricmanagerSha256 != null;
  70 assert useFabricmanager -> !useSettings;
  71
  72 let
  73   # Rewrites patches meant for the kernel/* folder structure to kernel-open/*
  74   rewritePatch =
  75     { from, to }:
  76     patch:
  77     runCommandLocal (builtins.baseNameOf patch)
  78       {
  79         inherit patch;
  80         nativeBuildInputs = [ patchutils ];
  81       }
  82       ''
  83         lsdiff \
  84           -p1 -i ${from}/'*' \
  85           "$patch" \
  86         | sort -u | sed -e 's/[*?]/\\&/g' \
  87         | xargs -I{} \
  88           filterdiff \
  89           --include={} \
  90           --strip=2 \
  91           --addoldprefix=a/${to}/ \
  92           --addnewprefix=b/${to}/ \
  93           --clean "$patch" > "$out"
  94       '';
  95
  96   nameSuffix = lib.optionalString (!libsOnly) "-${kernel.version}";
  97   pkgSuffix = lib.optionalString (lib.versionOlder version "304") "-pkg0";
  98   i686bundled = lib.versionAtLeast version "391" && !disable32Bit;
  99
 100   libPathFor = pkgs: lib.makeLibraryPath (with pkgs; [
 101     libdrm
 102     xorg.libXext
 103     xorg.libX11
 104     xorg.libXv
 105     xorg.libXrandr
 106     xorg.libxcb
 107     zlib
 108     stdenv.cc.cc
 109     wayland
 110     mesa
 111     libGL
 112     openssl
 113     dbus # for nvidia-powerd
 114   ]);
 115
 116   # maybe silly since we've ignored this previously and just unfree..
 117   throwLicense = throw ''
 118     Use of NVIDIA Software requires license acceptance of the license:
 119
 120       - License For Customer Use of NVIDIA Software [1]
 121
 122     You can express acceptance by setting acceptLicense to true your nixpkgs.config.
 123     Example:
 124
 125       configuration.nix:
 126         nixpkgs.config.allowUnfree = true;
 127         nixpkgs.config.nvidia.acceptLicense = true;
 128
 129       config.nix:
 130         allowUnfree = true;
 131         nvidia.acceptLicense = true;
 132
 133     [1]: https://www.nvidia.com/content/DriverDownloads/licence.php?lang=us
 134   '';
 135
 136   self = stdenv.mkDerivation {
 137     name = "nvidia-${if useFabricmanager then "dc" else "x11"}-${version}${nameSuffix}";
 138
 139     builder = ./builder.sh;
 140
 141     src =
 142       if !acceptLicense && (openSha256 == null) then throwLicense else
 143       if stdenv.hostPlatform.system == "x86_64-linux" then
 144         fetchurl
 145           {
 146             urls = if args ? url then [ args.url ] else [
 147               "https://us.download.nvidia.com/XFree86/Linux-x86_64/${version}/NVIDIA-Linux-x86_64-${version}${pkgSuffix}.run"
 148               "https://download.nvidia.com/XFree86/Linux-x86_64/${version}/NVIDIA-Linux-x86_64-${version}${pkgSuffix}.run"
 149             ];
 150             sha256 = sha256_64bit;
 151           }
 152       else if stdenv.hostPlatform.system == "i686-linux" then
 153         fetchurl
 154           {
 155             urls = if args ? url then [ args.url ] else [
 156               "https://us.download.nvidia.com/XFree86/Linux-x86/${version}/NVIDIA-Linux-x86-${version}${pkgSuffix}.run"
 157               "https://download.nvidia.com/XFree86/Linux-x86/${version}/NVIDIA-Linux-x86-${version}${pkgSuffix}.run"
 158             ];
 159             sha256 = sha256_32bit;
 160           }
 161       else if stdenv.hostPlatform.system == "aarch64-linux" && sha256_aarch64 != null then
 162         fetchurl
 163           {
 164             urls = if args ? url then [ args.url ] else [
 165               "https://us.download.nvidia.com/XFree86/aarch64/${version}/NVIDIA-Linux-aarch64-${version}${pkgSuffix}.run"
 166               "https://download.nvidia.com/XFree86/Linux-aarch64/${version}/NVIDIA-Linux-aarch64-${version}${pkgSuffix}.run"
 167             ];
 168             sha256 = sha256_aarch64;
 169           }
 170       else throw "nvidia-x11 does not support platform ${stdenv.hostPlatform.system}";
 171
 172     patches =
 173       if libsOnly then
 174         null
 175       else
 176         (
 177           patches
 178           ++ (builtins.map (rewritePatch {
 179             from = "kernel-open";
 180             to = "kernel";
 181           }) patchesOpen)
 182         );
 183     inherit prePatch postPatch patchFlags;
 184     inherit preInstall postInstall;
 185     inherit version useGLVND useProfiles;
 186     inherit (stdenv.hostPlatform) system;
 187     inherit i686bundled;
 188
 189     outputs = [ "out" ]
 190       ++ lib.optional i686bundled "lib32"
 191       ++ lib.optional (!libsOnly) "bin"
 192       ++ lib.optional (!libsOnly && firmware) "firmware";
 193     outputDev = if libsOnly then null else "bin";
 194
 195     kernel = if libsOnly then null else kernel.dev;
 196     kernelVersion = if libsOnly then null else kernel.modDirVersion;
 197
 198     makeFlags = lib.optionals (!libsOnly) (kernel.makeFlags ++ [
 199       "IGNORE_PREEMPT_RT_PRESENCE=1"
 200       "NV_BUILD_SUPPORTS_HMM=1"
 201       "SYSSRC=${kernel.dev}/lib/modules/${kernel.modDirVersion}/source"
 202       "SYSOUT=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
 203     ]);
 204
 205     hardeningDisable = [ "pic" "format" ];
 206
 207     dontStrip = true;
 208     dontPatchELF = true;
 209
 210     libPath = libPathFor pkgs;
 211     libPath32 = lib.optionalString i686bundled (libPathFor pkgsi686Linux);
 212
 213     nativeBuildInputs = [ perl nukeReferences which libarchive jq ]
 214       ++ lib.optionals (!libsOnly) kernel.moduleBuildDependencies;
 215
 216     disallowedReferences = lib.optionals (!libsOnly) [ kernel.dev ];
 217
 218     passthru =
 219       let
 220         fetchFromGithubOrNvidia = { owner, repo, rev, ... }@args:
 221           let
 222             args' = builtins.removeAttrs args [ "owner" "repo" "rev" ];
 223             baseUrl = "https://github.com/${owner}/${repo}";
 224           in
 225           fetchzip (args' // {
 226             urls = [
 227               "${baseUrl}/archive/${rev}.tar.gz"
 228               "https://download.nvidia.com/XFree86/${repo}/${repo}-${rev}.tar.bz2"
 229             ];
 230             # github and nvidia use different compression algorithms,
 231             #  use an invalid file extension to force detection.
 232             extension = "tar.??";
 233           });
 234       in
 235       {
 236         open = lib.mapNullable
 237           (hash: callPackage ./open.nix {
 238             inherit hash;
 239             nvidia_x11 = self;
 240             patches =
 241               (builtins.map (rewritePatch {
 242                 from = "kernel";
 243                 to = "kernel-open";
 244               }) patches)
 245               ++ patchesOpen;
 246             broken = brokenOpen;
 247           })
 248           openSha256;
 249         settings =
 250           if useSettings then
 251             (if settings32Bit then pkgsi686Linux.callPackage else callPackage) (import ./settings.nix self settingsSha256)
 252               {
 253                 withGtk2 = preferGtk2;
 254                 withGtk3 = !preferGtk2;
 255                 fetchFromGitHub = fetchFromGithubOrNvidia;
 256               } else { };
 257         persistenced =
 258           if usePersistenced then
 259             lib.mapNullable
 260               (hash: callPackage (import ./persistenced.nix self hash) {
 261                 fetchFromGitHub = fetchFromGithubOrNvidia;
 262               })
 263               persistencedSha256
 264           else { };
 265         fabricmanager =
 266           if useFabricmanager then
 267             lib.mapNullable (hash: callPackage (import ./fabricmanager.nix self hash) { }) fabricmanagerSha256
 268           else { };
 269         inherit persistencedVersion settingsVersion;
 270         compressFirmware = false;
 271         ibtSupport = ibtSupport || (lib.versionAtLeast version "530");
 272       } // lib.optionalAttrs (!i686bundled) {
 273         inherit lib32;
 274       };
 275
 276     meta = with lib; {
 277       homepage = "https://www.nvidia.com/object/unix.html";
 278       description = "${if useFabricmanager then "Data Center" else "X.org"} driver and kernel module for NVIDIA cards";
 279       license = licenses.unfreeRedistributable;
 280       platforms = [ "x86_64-linux" ]
 281         ++ lib.optionals (sha256_32bit != null) [ "i686-linux" ]
 282         ++ lib.optionals (sha256_aarch64 != null) [ "aarch64-linux" ];
 283       maintainers = with maintainers; [ kiskae edwtjo ];
 284       priority = 4; # resolves collision with xorg-server's "lib/xorg/modules/extensions/libglx.so"
 285       inherit broken;
 286     };
 287   };
 288
 289 in
 290 self