pkgs/os-specific/windows/cygwin-setup/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchcvs,
   5   autoconf,
   6   automake,
   7   libtool,
   8   flex,
   9   bison,
  10   pkg-config,
  11   zlib,
  12   bzip2,
  13   xz,
  14   libgcrypt,
  15 }:
  16
  17 stdenv.mkDerivation rec {
  18   pname = "cygwin-setup";
  19   version = "20131101";
  20
  21   src = fetchcvs {
  22     cvsRoot = ":pserver:anoncvs@cygwin.com:/cvs/cygwin-apps";
  23     module = "setup";
  24     date = version;
  25     sha256 = "024wxaaxkf7p1i78bh5xrsqmfz7ss2amigbfl2r5w9h87zqn9aq3";
  26   };
  27
  28   nativeBuildInputs = [
  29     autoconf
  30     automake
  31     libtool
  32     flex
  33     bison
  34     pkg-config
  35   ];
  36
  37   buildInputs =
  38     let
  39       mkStatic = lib.flip lib.overrideDerivation (o: {
  40         dontDisableStatic = true;
  41         configureFlags = lib.toList (o.configureFlags or [ ]) ++ [ "--enable-static" ];
  42         buildInputs = map mkStatic (o.buildInputs or [ ]);
  43         propagatedBuildInputs = map mkStatic (o.propagatedBuildInputs or [ ]);
  44       });
  45     in
  46     map mkStatic [
  47       zlib
  48       bzip2
  49       xz
  50       libgcrypt
  51     ];
  52
  53   configureFlags = [ "--disable-shared" ];
  54
  55   dontDisableStatic = true;
  56
  57   preConfigure = ''
  58     autoreconf -vfi
  59   '';
  60
  61   installPhase = ''
  62     install -vD setup.exe "$out/bin/setup.exe"
  63   '';
  64
  65   meta = {
  66     homepage = "https://sourceware.org/cygwin-apps/setup.html";
  67     description = "Tool for installing Cygwin";
  68     license = lib.licenses.gpl2Plus;
  69   };
  70 }