pkgs/servers/jitsi-videobridge/default.nix

   1 { lib, stdenv, fetchurl, makeWrapper, dpkg, jre_headless, openssl, nixosTests }:
   2
   3 let
   4   pname = "jitsi-videobridge2";
   5   version = "2.3-160-g97a1f15b";
   6   src = fetchurl {
   7     url = "https://download.jitsi.org/stable/${pname}_${version}-1_all.deb";
   8     sha256 = "fxAmpsScNTwSrITZYE2dsKTlGqlMcAAf8RVixpmcqvI=";
   9   };
  10 in
  11 stdenv.mkDerivation {
  12   inherit pname version src;
  13
  14   dontBuild = true;
  15
  16   nativeBuildInputs = [
  17     dpkg
  18     makeWrapper
  19   ];
  20
  21   installPhase = ''
  22     runHook preInstall
  23     substituteInPlace usr/share/jitsi-videobridge/jvb.sh \
  24       --replace "exec java" "exec ${jre_headless}/bin/java"
  25
  26     mkdir -p $out/{bin,share/jitsi-videobridge,etc/jitsi/videobridge}
  27     mv etc/jitsi/videobridge/logging.properties $out/etc/jitsi/videobridge/
  28     cp ${./logging.properties-journal} $out/etc/jitsi/videobridge/logging.properties-journal
  29     mv usr/share/jitsi-videobridge/* $out/share/jitsi-videobridge/
  30     ln -s $out/share/jitsi-videobridge/jvb.sh $out/bin/jitsi-videobridge
  31
  32     # - work around https://github.com/jitsi/jitsi-videobridge/issues/1547
  33     # - make libcrypto.so available at runtime for hardware AES
  34     wrapProgram $out/bin/jitsi-videobridge \
  35       --set VIDEOBRIDGE_GC_TYPE G1GC \
  36       --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ openssl ]}
  37     runHook postInstall
  38   '';
  39
  40   passthru.tests = {
  41     single-host-smoke-test = nixosTests.jitsi-meet;
  42   };
  43
  44   passthru.updateScript = ./update.sh;
  45
  46   meta = with lib; {
  47     description = "WebRTC compatible video router";
  48     longDescription = ''
  49       Jitsi Videobridge is an XMPP server component that allows for multiuser video communication.
  50       Unlike the expensive dedicated hardware videobridges, Jitsi Videobridge does not mix the video
  51       channels into a composite video stream, but only relays the received video channels to all call
  52       participants. Therefore, while it does need to run on a server with good network bandwidth,
  53       CPU horsepower is not that critical for performance.
  54     '';
  55     homepage = "https://github.com/jitsi/jitsi-videobridge";
  56     license = licenses.asl20;
  57     maintainers = teams.jitsi.members;
  58     platforms = platforms.linux;
  59     mainProgram = "jitsi-videobridge";
  60   };
  61 }