pkgs/servers/monitoring/prometheus/smokeping-prober.nix

   1 {
   2   lib,
   3   buildGoModule,
   4   fetchFromGitHub,
   5   nixosTests,
   6 }:
   7
   8 buildGoModule rec {
   9   pname = "smokeping_prober";
  10   version = "0.8.1";
  11
  12   ldflags =
  13     let
  14       setVars = rec {
  15         Version = version;
  16         Revision = "722200c4adbd6d1e5d847dfbbd9dec07aa4ca38d";
  17         Branch = Revision;
  18         BuildUser = "nix";
  19       };
  20       varFlags = lib.concatStringsSep " " (
  21         lib.mapAttrsToList (name: value: "-X github.com/prometheus/common/version.${name}=${value}") setVars
  22       );
  23     in
  24     [
  25       "${varFlags}"
  26       "-s"
  27       "-w"
  28     ];
  29
  30   src = fetchFromGitHub {
  31     owner = "SuperQ";
  32     repo = "smokeping_prober";
  33     rev = "v${version}";
  34     sha256 = "sha256-CqUkJLyxCuBDbfPLSXuGNlyg5POh6jYyXUxQ9tF+w3s=";
  35   };
  36   vendorHash = "sha256-iKAT10pD2ctVIBdDw/AmHYtoZDW9XC8ruIxqlVoAuWY=";
  37
  38   doCheck = true;
  39
  40   passthru.tests = { inherit (nixosTests.prometheus-exporters) smokeping; };
  41
  42   meta = with lib; {
  43     description = "Prometheus exporter for sending continual ICMP/UDP pings";
  44     mainProgram = "smokeping_prober";
  45     homepage = "https://github.com/SuperQ/smokeping_prober";
  46     license = licenses.asl20;
  47     maintainers = with maintainers; [ lukegb ];
  48   };
  49 }