pkgs/servers/nosql/influxdb2/cli.nix

   1 { buildGoModule
   2 , fetchFromGitHub
   3 , installShellFiles
   4 , lib
   5 , stdenv
   6 }:
   7
   8 let
   9   version = "2.7.5";
  10
  11   src = fetchFromGitHub {
  12     owner = "influxdata";
  13     repo = "influx-cli";
  14     rev = "v${version}";
  15     sha256 = "sha256-0Gyoy9T5pA+40k8kKybWBMtOfpKZxw3Vvp4ZB4ptcJs=";
  16   };
  17
  18 in buildGoModule {
  19   pname = "influx-cli";
  20   version = version;
  21   inherit src;
  22
  23   nativeBuildInputs = [ installShellFiles ];
  24
  25   vendorHash = "sha256-Ov0TPoMm0qi7kkWUUni677sCP1LwkT9+n3KHcAlQkDA=";
  26   subPackages = [ "cmd/influx" ];
  27
  28   ldflags = [ "-X main.commit=v${version}" "-X main.version=${version}" ];
  29
  30   postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  31     installShellCompletion --cmd influx \
  32       --bash <($out/bin/influx completion bash) \
  33       --zsh  <($out/bin/influx completion zsh)
  34   '';
  35
  36   meta = with lib; {
  37     description = "CLI for managing resources in InfluxDB v2";
  38     license = licenses.mit;
  39     homepage = "https://influxdata.com/";
  40     maintainers = with maintainers; [ abbradar ];
  41     mainProgram = "influx";
  42   };
  43 }