pkgs/servers/plik/programs.nix

   1 { lib, buildGoModule, fetchFromGitHub, makeWrapper, runCommand, nixosTests }:
   2
   3 let
   4   version = "1.3.8";
   5
   6   src = fetchFromGitHub {
   7     owner = "root-gg";
   8     repo = "plik";
   9     rev = version;
  10     hash = "sha256-WCtfkzlZnyzZDwNDBrW06bUbLYTL2C704Y7aXbiVi5c=";
  11   };
  12
  13   vendorHash = null;
  14
  15   meta = with lib; {
  16     homepage = "https://plik.root.gg/";
  17     description = "Scalable & friendly temporary file upload system";
  18     maintainers = with maintainers; [ freezeboy ];
  19     license = licenses.mit;
  20     mainProgram = "plik";
  21   };
  22
  23   postPatch = ''
  24     substituteInPlace server/common/version.go \
  25       --replace '"0.0.0"' '"${version}"'
  26   '';
  27
  28   passthru.tests = {
  29     inherit (nixosTests) plikd;
  30   };
  31
  32 in
  33 {
  34
  35   plik = buildGoModule {
  36     pname = "plik";
  37     inherit version meta src vendorHash postPatch passthru;
  38
  39     subPackages = [ "client" ];
  40     postInstall = ''
  41       mv $out/bin/client $out/bin/plik
  42     '';
  43   };
  44
  45   plikd-unwrapped = buildGoModule {
  46     pname = "plikd-unwrapped";
  47     inherit version src vendorHash postPatch passthru;
  48
  49     subPackages = [ "server" ];
  50     postFixup = ''
  51       mv $out/bin/server $out/bin/plikd
  52     '';
  53   };
  54 }