pkgs/servers/pulseaudio/hsphfpd.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   makeWrapper,
   6   perlPackages,
   7 }:
   8
   9 let
  10   perlLibs = with perlPackages; [
  11     NetDBus
  12     XMLTwig
  13     XMLParser
  14   ];
  15 in
  16 stdenv.mkDerivation {
  17   pname = "hsphfpd";
  18   version = "2020-12-05";
  19
  20   src = fetchFromGitHub {
  21     owner = "pali";
  22     repo = "hsphfpd-prototype";
  23     rev = "d294d064879591e9570ca3f444fa3eee2f269df8";
  24     sha256 = "0pm5rbsfrm04hnifzdmsyz17rjk8h9h6d19jaikjc5y36z03xf1c";
  25   };
  26
  27   nativeBuildInputs = [ makeWrapper ];
  28   buildInputs = [ perlPackages.perl ];
  29   dontBuild = true;
  30
  31   installPhase = ''
  32     runHook preInstall
  33
  34     mkdir -p $out/share/dbus-1/system.d
  35     cp org.hsphfpd.conf $out/share/dbus-1/system.d
  36
  37     mkdir -p $out/bin
  38     cp *.pl $out/bin
  39
  40     runHook postInstall
  41   '';
  42
  43   postFixup = ''
  44     for f in $out/bin/*.pl; do
  45       wrapProgram "$f" --set PERL5LIB "${perlPackages.makePerlPath perlLibs}"
  46     done
  47   '';
  48
  49   meta = with lib; {
  50     description = "Bluetooth HSP/HFP daemon";
  51     homepage = "https://github.com/pali/hsphfpd-prototype";
  52     license = licenses.artistic1;
  53     maintainers = with maintainers; [ gebner ];
  54     platforms = platforms.linux;
  55   };
  56 }