pkgs/tools/audio/beets/default.nix

   1 {
   2   lib,
   3   callPackage,
   4   fetchFromGitHub,
   5   python3Packages,
   6 }:
   7 /*
   8   ** To customize the enabled beets plugins, use the pluginOverrides input to the
   9   ** derivation.
  10   ** Examples:
  11   **
  12   ** Disabling a builtin plugin:
  13   ** beets.override { pluginOverrides = { beatport.enable = false; }; }
  14   **
  15   ** Enabling an external plugin:
  16   ** beets.override { pluginOverrides = {
  17   **   alternatives = { enable = true; propagatedBuildInputs = [ beetsPackages.alternatives ]; };
  18   ** }; }
  19 */
  20 lib.makeExtensible (self: {
  21   beets = self.beets-stable;
  22
  23   beets-stable = callPackage ./common.nix rec {
  24     inherit python3Packages;
  25     version = "2.2.0";
  26     src = fetchFromGitHub {
  27       owner = "beetbox";
  28       repo = "beets";
  29       rev = "v${version}";
  30       hash = "sha256-jhwXRgUUQJgQ/PLwvY1UfHCJ9UC8DcdBpE/janao0RM=";
  31     };
  32     extraPatches = [
  33       # Bash completion fix for Nix
  34       ./patches/bash-completion-always-print.patch
  35     ];
  36   };
  37
  38   beets-minimal = self.beets.override { disableAllPlugins = true; };
  39
  40   beets-unstable = callPackage ./common.nix {
  41     inherit python3Packages;
  42     version = "2.2.0-unstable-2024-12-02";
  43     src = fetchFromGitHub {
  44       owner = "beetbox";
  45       repo = "beets";
  46       rev = "f92c0ec8b14fbd59e58374fd123563123aef197b";
  47       hash = "sha256-jhwXRgUUQJgQ/PLwvY1UfHCJ9UC8DcdBpE/janao0RM=";
  48     };
  49     extraPatches = [
  50       # Bash completion fix for Nix
  51       ./patches/bash-completion-always-print.patch
  52     ];
  53   };
  54
  55   alternatives = callPackage ./plugins/alternatives.nix { beets = self.beets-minimal; };
  56   copyartifacts = callPackage ./plugins/copyartifacts.nix { beets = self.beets-minimal; };
  57
  58   extrafiles = throw "extrafiles is unmaintained since 2020 and broken since beets 2.0.0";
  59 })