pkgs/tools/audio/beets/plugins/copyartifacts.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   beets,
   5   python3Packages,
   6 }:
   7
   8 python3Packages.buildPythonApplication rec {
   9   pname = "beets-copyartifacts";
  10   version = "0.1.5";
  11
  12   src = fetchFromGitHub {
  13     repo = "beets-copyartifacts";
  14     owner = "adammillerio";
  15     rev = "v${version}";
  16     sha256 = "sha256-UTZh7T6Z288PjxFgyFxHnPt0xpAH3cnr8/jIrlJhtyU=";
  17   };
  18
  19   postPatch = ''
  20     sed -i -e '/install_requires/,/\]/{/beets/d}' setup.py
  21     sed -i -e '/namespace_packages/d' setup.py
  22     printf 'from pkgutil import extend_path\n__path__ = extend_path(__path__, __name__)\n' >beetsplug/__init__.py
  23
  24     # beets v2.1.0 compat
  25     # <https://github.com/beetbox/beets/commit/0e87389994a9969fa0930ffaa607609d02e286a8>
  26     sed -i -e 's/util\.py3_path/os.fsdecode/g' tests/_common.py
  27   '';
  28
  29   pytestFlagsArray = [ "-r fEs" ];
  30
  31   nativeCheckInputs = [
  32     python3Packages.pytestCheckHook
  33     beets
  34   ];
  35   preCheck = ''
  36     export HOME=$(mktemp -d)
  37   '';
  38
  39   meta = {
  40     description = "Beets plugin to move non-music files during the import process";
  41     homepage = "https://github.com/adammillerio/beets-copyartifacts";
  42     license = lib.licenses.mit;
  43     inherit (beets.meta) platforms;
  44   };
  45 }