pkgs/tools/games/gamemode/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , libgamemode32
   5 , makeWrapper
   6 , meson
   7 , ninja
   8 , pkg-config
   9 , dbus
  10 , inih
  11 , systemd
  12 , appstream
  13 , findutils
  14 , gawk
  15 , procps
  16 , nix-update-script
  17 }:
  18
  19 stdenv.mkDerivation (finalAttrs: {
  20   pname = "gamemode";
  21   version = "1.8.2";
  22
  23   src = fetchFromGitHub {
  24     owner = "FeralInteractive";
  25     repo = "gamemode";
  26     rev = "refs/tags/${finalAttrs.version}";
  27     hash = "sha256-JkDFhFLUHlgD6RKxlxMjrSF2zQ4AWmRUQMLbWYwIZmg=";
  28   };
  29
  30   outputs = [ "out" "dev" "lib" "man" ];
  31
  32   patches = [
  33     # Add @libraryPath@ template variable to fix loading the PRELOAD library
  34     ./preload-nix-workaround.patch
  35   ];
  36
  37   postPatch = ''
  38     substituteInPlace data/gamemoderun \
  39       --subst-var-by libraryPath ${lib.makeLibraryPath ([
  40         (placeholder "lib")
  41       ] ++ lib.optionals (stdenv.hostPlatform.system == "x86_64-linux") [
  42         # Support wrapping 32bit applications on a 64bit linux system
  43         libgamemode32
  44       ])}
  45   '';
  46
  47   nativeBuildInputs = [
  48     makeWrapper
  49     meson
  50     ninja
  51     pkg-config
  52   ];
  53
  54   buildInputs = [
  55     dbus
  56     inih
  57     systemd
  58   ];
  59
  60   mesonFlags = [
  61     "-Dwith-pam-limits-dir=etc/security/limits.d"
  62     "-Dwith-systemd-user-unit-dir=lib/systemd/user"
  63     "-Dwith-systemd-group-dir=lib/sysusers.d"
  64
  65     # The meson builder installs internal executables to $lib/lib by
  66     # default, but they should be installed to "$out". It's also more
  67     # appropriate to install these executables under a libexec
  68     # directory instead of lib.
  69     "--libexecdir=libexec"
  70   ];
  71
  72   doCheck = true;
  73   nativeCheckInputs = [
  74     appstream
  75   ];
  76
  77   postFixup = ''
  78     # Add $lib/lib to gamemoded & gamemode-simulate-game's rpath since
  79     # they use dlopen to load libgamemode. Can't use makeWrapper since
  80     # it would break the security wrapper in the NixOS module.
  81     for bin in "$out/bin/gamemoded" "$out/bin/gamemode-simulate-game"; do
  82       patchelf --set-rpath "$lib/lib:$(patchelf --print-rpath "$bin")" "$bin"
  83     done
  84
  85     wrapProgram "$out/bin/gamemodelist" \
  86       --prefix PATH : ${lib.makeBinPath [
  87         findutils
  88         gawk
  89         procps
  90       ]}
  91   '';
  92
  93   passthru.updateScript = nix-update-script { };
  94
  95   meta = with lib; {
  96     description = "Optimise Linux system performance on demand";
  97     homepage = "https://feralinteractive.github.io/gamemode";
  98     changelog = "https://github.com/FeralInteractive/gamemode/blob/${finalAttrs.version}/CHANGELOG.md";
  99     license = licenses.bsd3;
 100     maintainers = with maintainers; [ kira-bruneau ];
 101     platforms = platforms.linux;
 102     mainProgram = "gamemoderun"; # Requires NixOS module to run
 103   };
 104 })