pkgs/tools/inputmethods/fcitx5/fcitx5-chinese-addons.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , fetchFromGitHub
   5 , cmake
   6 , extra-cmake-modules
   7 , boost
   8 , libime
   9 , fcitx5
  10 , fcitx5-qt
  11 , fcitx5-lua
  12 , qtwebengine
  13 , opencc
  14 , curl
  15 , fmt
  16 , qtbase
  17 , luaSupport ? true
  18 }:
  19
  20 let
  21   pyStrokeVer = "20121124";
  22   pyStroke = fetchurl {
  23     url = "http://download.fcitx-im.org/data/py_stroke-${pyStrokeVer}.tar.gz";
  24     hash = "sha256-jrEoqb+kOVLmfPL87h/RNMb0z9MXvC9sOKYV9etk4kg=";
  25   };
  26   pyTableVer = "20121124";
  27   pyTable = fetchurl {
  28     url = "http://download.fcitx-im.org/data/py_table-${pyTableVer}.tar.gz";
  29     hash = "sha256-QhRqyX3mwT1V+eme2HORX0xmc56cEVMqNFVrrfl5LAQ=";
  30   };
  31 in
  32
  33 stdenv.mkDerivation rec {
  34   pname = "fcitx5-chinese-addons";
  35   version = "5.1.7";
  36
  37   src = fetchFromGitHub {
  38     owner = "fcitx";
  39     repo = pname;
  40     rev = version;
  41     hash = "sha256-vtIzm8ia5hC0JdsGNopIHdAd8RDVgrbtVvj1Jh+gE94=";
  42   };
  43
  44   nativeBuildInputs = [
  45     cmake
  46     extra-cmake-modules
  47     boost
  48     fcitx5-lua
  49   ];
  50
  51   prePatch = ''
  52     ln -s ${pyStroke} modules/pinyinhelper/$(stripHash ${pyStroke})
  53     ln -s ${pyTable} modules/pinyinhelper/$(stripHash ${pyTable})
  54   '';
  55
  56   buildInputs = [
  57     fcitx5
  58     fcitx5-qt
  59     libime
  60     curl
  61     opencc
  62     qtwebengine
  63     fmt
  64   ] ++ lib.optional luaSupport fcitx5-lua;
  65
  66   cmakeFlags = [
  67     (lib.cmakeBool "USE_QT6" (lib.versions.major qtbase.version == "6"))
  68   ];
  69
  70   dontWrapQtApps = true;
  71
  72   meta = with lib; {
  73     description = "Addons related to Chinese, including IME previous bundled inside fcitx4";
  74     mainProgram = "scel2org5";
  75     homepage = "https://github.com/fcitx/fcitx5-chinese-addons";
  76     license = with licenses; [ gpl2Plus lgpl21Plus ];
  77     maintainers = with maintainers; [ poscat ];
  78     platforms = platforms.linux;
  79   };
  80 }