pkgs/tools/security/bitwarden-directory-connector/default.nix

   1 {
   2   lib,
   3   buildNpmPackage,
   4   electron,
   5   fetchFromGitHub,
   6   buildPackages,
   7   python3,
   8   pkg-config,
   9   libsecret,
  10   nodejs_18,
  11 }:
  12
  13 let
  14   common = { name, npmBuildScript, installPhase }: buildNpmPackage rec {
  15     pname = name;
  16     version = "2024.10.0";
  17     nodejs = nodejs_18;
  18
  19     src = fetchFromGitHub {
  20       owner = "bitwarden";
  21       repo = "directory-connector";
  22       rev = "v${version}";
  23       hash = "sha256-jisMEuIpTWCy+N1QeERf+05tsugY0f+H2ntcRcFKkgo=";
  24     };
  25
  26     postPatch = ''
  27       ${lib.getExe buildPackages.jq} 'del(.scripts.preinstall)' package.json > package.json.tmp
  28       mv -f package.json{.tmp,}
  29
  30       substituteInPlace electron-builder.json \
  31         --replace-fail '"afterSign": "scripts/notarize.js",' "" \
  32         --replace-fail "AppImage" "dir"
  33     '';
  34
  35     npmDepsHash = "sha256-Zi7EHzQSSrZ6XGGV1DOASuddYA4svXQc1eGmchcLFBc=";
  36
  37     env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
  38
  39     makeCacheWritable = true;
  40     inherit npmBuildScript installPhase;
  41
  42     buildInputs = [
  43       libsecret
  44     ];
  45
  46     nativeBuildInputs = [
  47       (python3.withPackages (ps: with ps; [ setuptools ]))
  48       pkg-config
  49     ];
  50
  51     meta = with lib; {
  52       description = "LDAP connector for Bitwarden";
  53       homepage = "https://github.com/bitwarden/directory-connector";
  54       license = licenses.gpl3Only;
  55       maintainers = with maintainers; [ Silver-Golden SuperSandro2000 ];
  56       platforms = platforms.linux;
  57       mainProgram = name;
  58     };
  59   };
  60 in {
  61   bitwarden-directory-connector = common {
  62     name = "bitwarden-directory-connector";
  63     npmBuildScript = "build:dist";
  64     installPhase = ''
  65       runHook preInstall
  66
  67       npm exec electron-builder -- \
  68         --dir \
  69         -c.electronDist=${electron.dist} \
  70         -c.electronVersion=${electron.version} \
  71         -c.npmRebuild=false
  72
  73       mkdir -p $out/share/bitwarden-directory-connector $out/bin
  74       cp -r dist/*-unpacked/{locales,resources{,.pak}} $out/share/bitwarden-directory-connector
  75
  76       makeWrapper ${lib.getExe electron} $out/bin/bitwarden-directory-connector \
  77         --add-flags $out/share/bitwarden-directory-connector/resources/app.asar \
  78         --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime}}" \
  79         --set-default ELECTRON_IS_DEV 0 \
  80         --inherit-argv0
  81
  82       runHook postInstall
  83     '';
  84   };
  85
  86   bitwarden-directory-connector-cli = common {
  87     name = "bitwarden-directory-connector-cli";
  88     npmBuildScript = "build:cli:prod";
  89     installPhase = ''
  90       runHook preInstall
  91
  92       mkdir -p $out/libexec/bitwarden-directory-connector
  93       cp -R build-cli node_modules $out/libexec/bitwarden-directory-connector
  94
  95       # needs to be wrapped with nodejs so that it can be executed
  96       chmod +x $out/libexec/bitwarden-directory-connector/build-cli/bwdc.js
  97       mkdir -p $out/bin
  98       ln -s $out/libexec/bitwarden-directory-connector/build-cli/bwdc.js $out/bin/bitwarden-directory-connector-cli
  99
 100       runHook postInstall
 101     '';
 102   };
 103 }