pkgs/tools/security/gopass/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   makeWrapper,
   5   buildGoModule,
   6   fetchFromGitHub,
   7   installShellFiles,
   8   git,
   9   gnupg,
  10   xclip,
  11   wl-clipboard,
  12   passAlias ? false,
  13   apple-sdk_14,
  14   testers,
  15   nix-update-script,
  16   gopass,
  17 }:
  18
  19 buildGoModule rec {
  20   pname = "gopass";
  21   version = "1.15.15";
  22
  23   nativeBuildInputs = [
  24     installShellFiles
  25     makeWrapper
  26   ];
  27
  28   buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [
  29     # For ScreenCaptureKit.h, see https://github.com/NixOS/nixpkgs/pull/358760#discussion_r1858327365
  30     apple-sdk_14
  31   ];
  32
  33   src = fetchFromGitHub {
  34     owner = "gopasspw";
  35     repo = "gopass";
  36     rev = "v${version}";
  37     hash = "sha256-GL0vnrNz9vcdybubYIjiK0tDH3L4lNWNo+rAAWv7d8o=";
  38   };
  39
  40   vendorHash = "sha256-dDy7eQe/JtAsB+cPONiqUwcCsbisCLzY/5YQaH9w2Yg=";
  41
  42   subPackages = [ "." ];
  43
  44   ldflags = [
  45     "-s"
  46     "-w"
  47     "-X main.version=${version}"
  48     "-X main.commit=${src.rev}"
  49   ];
  50
  51   wrapperPath = lib.makeBinPath (
  52     [
  53       git
  54       gnupg
  55       xclip
  56     ]
  57     ++ lib.optional stdenv.hostPlatform.isLinux wl-clipboard
  58   );
  59
  60   postInstall =
  61     ''
  62       installManPage gopass.1
  63       installShellCompletion --cmd gopass \
  64         --zsh zsh.completion \
  65         --bash bash.completion \
  66         --fish fish.completion
  67     ''
  68     + lib.optionalString passAlias ''
  69       ln -s $out/bin/gopass $out/bin/pass
  70     '';
  71
  72   postFixup = ''
  73     wrapProgram $out/bin/gopass \
  74       --prefix PATH : "${wrapperPath}" \
  75       --set GOPASS_NO_REMINDER true
  76   '';
  77   passthru = {
  78     inherit wrapperPath;
  79
  80     tests.version = testers.testVersion {
  81       package = gopass;
  82     };
  83
  84     updateScript = nix-update-script { };
  85   };
  86
  87   meta = with lib; {
  88     description = "Slightly more awesome Standard Unix Password Manager for Teams. Written in Go";
  89     homepage = "https://www.gopass.pw/";
  90     license = licenses.mit;
  91     maintainers = with maintainers; [
  92       rvolosatovs
  93       sikmir
  94     ];
  95     changelog = "https://github.com/gopasspw/gopass/blob/v${version}/CHANGELOG.md";
  96
  97     longDescription = ''
  98       gopass is a rewrite of the pass password manager in Go with the aim of
  99       making it cross-platform and adding additional features. Our target
 100       audience are professional developers and sysadmins (and especially teams
 101       of those) who are well versed with a command line interface. One explicit
 102       goal for this project is to make it more approachable to non-technical
 103       users. We go by the UNIX philosophy and try to do one thing and do it
 104       well, providing a stellar user experience and a sane, simple interface.
 105     '';
 106     mainProgram = "gopass";
 107   };
 108 }