pkgs/tools/typesetting/tectonic/biber.nix

   1 /*
   2   This package, `biber-for-tectonic`, provides a compatible version of `biber`
   3   as an optional runtime dependency of `tectonic`.
   4
   5   The development of tectonic is slowing down recently, such that its `biber`
   6   dependency has been lagging behind the one in the nixpkgs `texlive` bundle.
   7   See:
   8
   9   https://github.com/tectonic-typesetting/tectonic/discussions/1122
  10
  11   It is now feasible to track the biber dependency in nixpkgs, as the
  12   version bump is not very frequent, and it would provide a more complete
  13   user experience of tectonic in nixpkgs.
  14 */
  15
  16 {
  17   lib,
  18   fetchFromGitHub,
  19   fetchpatch,
  20   biber,
  21 }:
  22
  23 let
  24   version = "2.17";
  25 in
  26 (biber.override {
  27   /*
  28     It is necessary to first override the `version` data here, which is
  29     passed to `buildPerlModule`, and then to `mkDerivation`.
  30
  31     If we simply do `biber.overrideAttrs` the resulting package `name`
  32     would be incorrect, since it has already been preprocessed by
  33     `buildPerlModule`.
  34   */
  35   texlive.pkgs.biber.texsource = {
  36     inherit version;
  37     inherit (biber) pname meta;
  38   };
  39 }).overrideAttrs
  40   (prevAttrs: {
  41     src = fetchFromGitHub {
  42       owner = "plk";
  43       repo = "biber";
  44       rev = "v${version}";
  45       hash = "sha256-Tt2sN2b2NGxcWyZDj5uXNGC8phJwFRiyH72n3yhFCi0=";
  46     };
  47     patches = [
  48       # Perl>=5.36.0 compatibility
  49       (fetchpatch {
  50         url = "https://patch-diff.githubusercontent.com/raw/plk/biber/pull/411.patch";
  51         hash = "sha256-osgldRVfe3jnMSOMnAMQSB0Ymc1s7J6KtM2ig3c93SE=";
  52       })
  53     ];
  54     meta = prevAttrs.meta // {
  55       maintainers = with lib.maintainers; [
  56         doronbehar
  57         bryango
  58       ];
  59     };
  60   })