pkgs/os-specific/linux/kernel/linux-rt-5.4.nix

   1 { lib, buildLinux, fetchurl
   2 , kernelPatches ? [ ]
   3 , structuredExtraConfig ? {}
   4 , extraMeta ? {}
   5 , argsOverride ? {}
   6 , ... } @ args:
   7
   8 let
   9   version = "5.4.278-rt91"; # updated by ./update-rt.sh
  10   branch = lib.versions.majorMinor version;
  11   kversion = builtins.elemAt (lib.splitString "-" version) 0;
  12 in buildLinux (args // {
  13   inherit version;
  14   pname = "linux-rt";
  15
  16   src = fetchurl {
  17     url = "mirror://kernel/linux/kernel/v5.x/linux-${kversion}.tar.xz";
  18     sha256 = "1245zf7vk2fyprw9fspljqy9wlzma9bayri7xx2g8iam2430d875";
  19   };
  20
  21   kernelPatches = let rt-patch = {
  22     name = "rt";
  23     patch = fetchurl {
  24       url = "mirror://kernel/linux/kernel/projects/rt/${branch}/older/patch-${version}.patch.xz";
  25       sha256 = "0s1ars3d18jg55kpvk6q5b6rk66c74d2khd2mxzdm5ifgm47047k";
  26     };
  27   }; in [ rt-patch ] ++ kernelPatches;
  28
  29   structuredExtraConfig = with lib.kernel; {
  30     PREEMPT_RT = yes;
  31     # Fix error: unused option: PREEMPT_RT.
  32     EXPERT = yes; # PREEMPT_RT depends on it (in kernel/Kconfig.preempt)
  33     # Fix error: option not set correctly: PREEMPT_VOLUNTARY (wanted 'y', got 'n').
  34     PREEMPT_VOLUNTARY = lib.mkForce no; # PREEMPT_RT deselects it.
  35     # Fix error: unused option: RT_GROUP_SCHED.
  36     RT_GROUP_SCHED = lib.mkForce (option no); # Removed by sched-disable-rt-group-sched-on-rt.patch.
  37   } // structuredExtraConfig;
  38
  39   extraMeta = extraMeta // {
  40     inherit branch;
  41   };
  42 } // argsOverride)