pkgs/os-specific/linux/nvidia-x11/default.nix

   1 { lib, callPackage, fetchFromGitHub, fetchgit, fetchpatch, stdenv, pkgsi686Linux }:
   2
   3 let
   4   generic = args: let
   5     imported = import ./generic.nix args;
   6   in callPackage imported {
   7     lib32 = (pkgsi686Linux.callPackage imported {
   8       libsOnly = true;
   9       kernel = null;
  10     }).out;
  11   };
  12
  13   kernel = callPackage # a hacky way of extracting parameters from callPackage
  14     ({ kernel, libsOnly ? false }: if libsOnly then { } else kernel) { };
  15
  16   selectHighestVersion = a: b: if lib.versionOlder a.version b.version
  17     then b
  18     else a;
  19
  20   # https://forums.developer.nvidia.com/t/linux-6-7-3-545-29-06-550-40-07-error-modpost-gpl-incompatible-module-nvidia-ko-uses-gpl-only-symbol-rcu-read-lock/280908/19
  21   rcu_patch = fetchpatch {
  22     url = "https://github.com/gentoo/gentoo/raw/c64caf53/x11-drivers/nvidia-drivers/files/nvidia-drivers-470.223.02-gpl-pfn_valid.patch";
  23     hash = "sha256-eZiQQp2S/asE7MfGvfe6dA/kdCvek9SYa/FFGp24dVg=";
  24   };
  25
  26   # Fixes framebuffer with linux 6.11
  27   fbdev_linux_611_patch = fetchpatch {
  28     url = "https://patch-diff.githubusercontent.com/raw/NVIDIA/open-gpu-kernel-modules/pull/692.patch";
  29     hash = "sha256-OYw8TsHDpBE5DBzdZCBT45+AiznzO9SfECz5/uXN5Uc=";
  30   };
  31
  32   # Fixes drm device not working with linux 6.12
  33   # https://github.com/NVIDIA/open-gpu-kernel-modules/issues/712
  34   drm_fop_flags_linux_612_patch  = fetchpatch {
  35     url = "https://github.com/Binary-Eater/open-gpu-kernel-modules/commit/8ac26d3c66ea88b0f80504bdd1e907658b41609d.patch";
  36     hash = "sha256-+SfIu3uYNQCf/KXhv4PWvruTVKQSh4bgU1moePhe57U=";
  37   };
  38 in
  39 rec {
  40   mkDriver = generic;
  41
  42   # Official Unix Drivers - https://www.nvidia.com/en-us/drivers/unix/
  43   # Branch/Maturity data - http://people.freedesktop.org/~aplattner/nvidia-versions.txt
  44
  45   # Policy: use the highest stable version as the default (on our master).
  46   stable = if stdenv.hostPlatform.system == "i686-linux" then legacy_390 else latest;
  47
  48   production = generic {
  49     version = "550.135";
  50     sha256_64bit = "sha256-ESBH9WRABWkOdiFBpVtCIZXKa5DvQCSke61MnoGHiKk=";
  51     sha256_aarch64 = "sha256-uyBCVhGZ637wv9JAp6Bq0A4e5aQ84jz/5iBgXdPr2FU=";
  52     openSha256 = "sha256-426lonLlCk4jahU4waAilYiRUv6bkLMuEpOLkCwcutE=";
  53     settingsSha256 = "sha256-4B61Q4CxDqz/BwmDx6EOtuXV/MNJbaZX+hj/Szo1z1Q=";
  54     persistencedSha256 = "sha256-FXKOTLbjhoGbO3q6kRuRbHw2pVUkOYTbTX2hyL/az94=";
  55   };
  56
  57   latest = selectHighestVersion production (generic {
  58     version = "560.35.03";
  59     sha256_64bit = "sha256-8pMskvrdQ8WyNBvkU/xPc/CtcYXCa7ekP73oGuKfH+M=";
  60     sha256_aarch64 = "sha256-s8ZAVKvRNXpjxRYqM3E5oss5FdqW+tv1qQC2pDjfG+s=";
  61     openSha256 = "sha256-/32Zf0dKrofTmPZ3Ratw4vDM7B+OgpC4p7s+RHUjCrg=";
  62     settingsSha256 = "sha256-kQsvDgnxis9ANFmwIwB7HX5MkIAcpEEAHc8IBOLdXvk=";
  63     persistencedSha256 = "sha256-E2J2wYYyRu7Kc3MMZz/8ZIemcZg68rkzvqEwFAL3fFs=";
  64     patchesOpen = [ fbdev_linux_611_patch ];
  65
  66     broken = kernel.kernelAtLeast "6.12";
  67   });
  68
  69   beta = selectHighestVersion latest (generic {
  70     version = "565.57.01";
  71     sha256_64bit = "sha256-buvpTlheOF6IBPWnQVLfQUiHv4GcwhvZW3Ks0PsYLHo=";
  72     sha256_aarch64 = "sha256-aDVc3sNTG4O3y+vKW87mw+i9AqXCY29GVqEIUlsvYfE=";
  73     openSha256 = "sha256-/tM3n9huz1MTE6KKtTCBglBMBGGL/GOHi5ZSUag4zXA=";
  74     settingsSha256 = "sha256-H7uEe34LdmUFcMcS6bz7sbpYhg9zPCb/5AmZZFTx1QA=";
  75     persistencedSha256 = "sha256-hdszsACWNqkCh8G4VBNitDT85gk9gJe1BlQ8LdrYIkg=";
  76     patchesOpen = [ drm_fop_flags_linux_612_patch ];
  77   });
  78
  79   # Vulkan developer beta driver
  80   # See here for more information: https://developer.nvidia.com/vulkan-driver
  81   vulkan_beta = generic rec {
  82     version = "550.40.80";
  83     persistencedVersion = "550.54.14";
  84     settingsVersion = "550.54.14";
  85     sha256_64bit = "sha256-fuI9G9KHCCddtPNDz+8FAkporSB7G97UU/pw4KGGZOE=";
  86     openSha256 = "sha256-+soDdbklk8wr/G5cj4BzZ8ql0zeHSswJ2OkOv59uMp0=";
  87     settingsSha256 = "sha256-m2rNASJp0i0Ez2OuqL+JpgEF0Yd8sYVCyrOoo/ln2a4=";
  88     persistencedSha256 = "sha256-XaPN8jVTjdag9frLPgBtqvO/goB5zxeGzaTU0CdL6C4=";
  89     url = "https://developer.nvidia.com/downloads/vulkan-beta-${lib.concatStrings (lib.splitVersion version)}-linux";
  90
  91     broken = kernel.kernelAtLeast "6.12";
  92   };
  93
  94   # data center driver compatible with current default cudaPackages
  95   dc = dc_520;
  96   dc_520 = generic rec {
  97     version = "520.61.05";
  98     url = "https://us.download.nvidia.com/tesla/${version}/NVIDIA-Linux-x86_64-${version}.run";
  99     sha256_64bit = "sha256-EPYWZwOur/6iN/otDMrNDpNXr1mzu8cIqQl8lXhQlzU==";
 100     fabricmanagerSha256 = "sha256-o8Kbmkg7qczKQclaGvEyXNzEOWq9ZpQZn9syeffnEiE==";
 101     useSettings = false;
 102     usePersistenced = false;
 103     useFabricmanager = true;
 104
 105     patches = [ rcu_patch ];
 106
 107     broken = kernel.kernelAtLeast "6.5";
 108   };
 109
 110   dc_535 = generic rec {
 111     version = "535.154.05";
 112     url = "https://us.download.nvidia.com/tesla/${version}/NVIDIA-Linux-x86_64-${version}.run";
 113     sha256_64bit = "sha256-fpUGXKprgt6SYRDxSCemGXLrEsIA6GOinp+0eGbqqJg=";
 114     persistencedSha256 = "sha256-d0Q3Lk80JqkS1B54Mahu2yY/WocOqFFbZVBh+ToGhaE=";
 115     fabricmanagerSha256 = "sha256-/HQfV7YA3MYVmre/sz897PF6tc6MaMiS/h7Q10m2p/o=";
 116     useSettings = false;
 117     usePersistenced = true;
 118     useFabricmanager = true;
 119
 120     patches = [ rcu_patch ];
 121   };
 122
 123   # Update note:
 124   # If you add a legacy driver here, also update `top-level/linux-kernels.nix`,
 125   # adding to the `nvidia_x11_legacy*` entries.
 126
 127   # Last one without the bug reported here:
 128   # https://bbs.archlinux.org/viewtopic.php?pid=2155426#p2155426
 129   legacy_535 = generic {
 130     version = "535.216.01";
 131     sha256_64bit = "sha256-Xd6hFHgQAS4zlnwxgTQbzWYkvT1lTGP4Rd+DO07Oavc=";
 132     sha256_aarch64 = "sha256-SGmuA0W1iSsqUK7VZsgibT4HgT0RkKpGb+ul6eIbM7k=";
 133     openSha256 = "sha256-ey96oMbY32ahcHSOj1+MykvJrep6mhHPVl+V8+B2ZDk=";
 134     settingsSha256 = "sha256-9PgaYJbP1s7hmKCYmkuLQ58nkTruhFdHAs4W84KQVME=";
 135     persistencedSha256 = "sha256-ckF/BgDA6xSFqFk07rn3HqXuR0iGfwA4PRxpP38QZgw=";
 136   };
 137
 138   # Last one supporting Kepler architecture
 139   legacy_470 = generic {
 140     version = "470.256.02";
 141     sha256_64bit = "sha256-1kUYYt62lbsER/O3zWJo9z6BFowQ4sEFl/8/oBNJsd4=";
 142     sha256_aarch64 = "sha256-e+QvE+S3Fv3JRqC9ZyxTSiCu8gJdZXSz10gF/EN6DY0=";
 143     settingsSha256 = "sha256-kftQ4JB0iSlE8r/Ze/+UMnwLzn0nfQtqYXBj+t6Aguk=";
 144     persistencedSha256 = "sha256-iYoSib9VEdwjOPBP1+Hx5wCIMhW8q8cCHu9PULWfnyQ=";
 145   };
 146
 147   # Last one supporting x86
 148   legacy_390 = let
 149     # Source corresponding to https://aur.archlinux.org/packages/nvidia-390xx-dkms
 150     aurPatches = fetchgit {
 151       url = "https://aur.archlinux.org/nvidia-390xx-utils.git";
 152       rev = "ebb48c240ce329e89ad3b59e78c8c708f46f27b3";
 153       hash = "sha256-AGx3/EQ81awBMs6rrXTGWJmyq+UjBCPp6/9z1BQBB9E=";
 154     };
 155     patchset = [
 156       "kernel-4.16+-memory-encryption.patch"
 157       "kernel-6.2.patch"
 158       "kernel-6.3.patch"
 159       "kernel-6.4.patch"
 160       "kernel-6.5.patch"
 161       "kernel-6.6.patch"
 162       "kernel-6.8.patch"
 163       "gcc-14.patch"
 164       "kernel-6.10.patch"
 165     ];
 166   in generic {
 167     version = "390.157";
 168     sha256_32bit = "sha256-VdZeCkU5qct5YgDF8Qgv4mP7CVHeqvlqnP/rioD3B5k=";
 169     sha256_64bit = "sha256-W+u8puj+1da52BBw+541HxjtxTSVJVPL3HHo/QubMoo=";
 170     settingsSha256 = "sha256-uJZO4ak/w/yeTQ9QdXJSiaURDLkevlI81de0q4PpFpw=";
 171     persistencedSha256 = "sha256-NuqUQbVt80gYTXgIcu0crAORfsj9BCRooyH3Gp1y1ns=";
 172
 173     patches = map (patch: "${aurPatches}/${patch}") patchset;
 174     broken = kernel.kernelAtLeast "6.11 ";
 175
 176     # fixes the bug described in https://bbs.archlinux.org/viewtopic.php?pid=2083439#p2083439
 177     # see https://bbs.archlinux.org/viewtopic.php?pid=2083651#p2083651
 178     # and https://bbs.archlinux.org/viewtopic.php?pid=2083699#p2083699
 179     postInstall = ''
 180       mv $out/lib/tls/* $out/lib
 181       rmdir $out/lib/tls
 182     '';
 183   };
 184
 185   legacy_340 = let
 186     # Source corresponding to https://aur.archlinux.org/packages/nvidia-340xx-dkms
 187     aurPatches = fetchFromGitHub {
 188       owner = "archlinux-jerry";
 189       repo = "nvidia-340xx";
 190       rev = "7616dfed253aa93ca7d2e05caf6f7f332c439c90";
 191       hash = "sha256-1qlYc17aEbLD4W8XXn1qKryBk2ltT6cVIv5zAs0jXZo=";
 192     };
 193     patchset = [
 194       "0001-kernel-5.7.patch"
 195       "0002-kernel-5.8.patch"
 196       "0003-kernel-5.9.patch"
 197       "0004-kernel-5.10.patch"
 198       "0005-kernel-5.11.patch"
 199       "0006-kernel-5.14.patch"
 200       "0007-kernel-5.15.patch"
 201       "0008-kernel-5.16.patch"
 202       "0009-kernel-5.17.patch"
 203       "0010-kernel-5.18.patch"
 204       "0011-kernel-6.0.patch"
 205       "0012-kernel-6.2.patch"
 206       "0013-kernel-6.3.patch"
 207       "0014-kernel-6.5.patch"
 208       "0015-kernel-6.6.patch"
 209     ];
 210   in generic {
 211     version = "340.108";
 212     sha256_32bit = "1jkwa1phf0x4sgw8pvr9d6krmmr3wkgwyygrxhdazwyr2bbalci0";
 213     sha256_64bit = "06xp6c0sa7v1b82gf0pq0i5p0vdhmm3v964v0ypw36y0nzqx8wf6";
 214     settingsSha256 = "0zm29jcf0mp1nykcravnzb5isypm8l8mg2gpsvwxipb7nk1ivy34";
 215     persistencedSha256 = "1ax4xn3nmxg1y6immq933cqzw6cj04x93saiasdc0kjlv0pvvnkn";
 216     useGLVND = false;
 217
 218     broken = kernel.kernelAtLeast "6.7";
 219     patches = map (patch: "${aurPatches}/${patch}") patchset;
 220
 221     # fixes the bug described in https://bbs.archlinux.org/viewtopic.php?pid=2083439#p2083439
 222     # see https://bbs.archlinux.org/viewtopic.php?pid=2083651#p2083651
 223     # and https://bbs.archlinux.org/viewtopic.php?pid=2083699#p2083699
 224     postInstall = ''
 225       mv $out/lib/tls/* $out/lib
 226       rmdir $out/lib/tls
 227     '';
 228   };
 229 }