pkgs/os-specific/linux/rtl8723ds/default.nix

   1 { lib, stdenv, fetchFromGitHub, kernel, bc }:
   2
   3 stdenv.mkDerivation {
   4   pname = "rtl8723ds";
   5   version = "${kernel.version}-unstable-2023-11-14";
   6
   7   src = fetchFromGitHub {
   8     owner = "lwfinger";
   9     repo = "rtl8723ds";
  10     rev = "52e593e8c889b68ba58bd51cbdbcad7fe71362e4";
  11     sha256 = "sha256-SszvDuWN9opkXyVQAOLjnNtPp93qrKgnGvzK0y7Y9b0=";
  12   };
  13
  14   hardeningDisable = [ "pic" ];
  15
  16   nativeBuildInputs = [ bc ] ++ kernel.moduleBuildDependencies;
  17
  18   makeFlags = [
  19     "ARCH=${stdenv.hostPlatform.linuxArch}"
  20   ] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
  21     "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
  22   ];
  23
  24   postPatch = ''
  25     substituteInPlace ./Makefile \
  26       --replace /lib/modules/ "${kernel.dev}/lib/modules/" \
  27       --replace "/sbin/depmod" "#" \
  28       --replace '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  29   '';
  30
  31   preInstall = ''
  32     mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  33   '';
  34
  35   enableParallelBuilding = true;
  36
  37   meta = {
  38     description = "Linux driver for RTL8723DS";
  39     homepage = "https://github.com/lwfinger/rtl8723ds";
  40     license = lib.licenses.gpl2Only;
  41     platforms = lib.platforms.linux;
  42     maintainers = with lib.maintainers; [ chuangzhu ];
  43   };
  44 }