pkgs/os-specific/linux/ryzen-smu/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , kernel
   5 }:
   6
   7 let
   8   version = "0.1.5-unstable-2024-01-03";
   9
  10   ## Upstream has not been merging PRs.
  11   ## Nixpkgs maintainers are providing a
  12   ## repo with PRs merged until upstream is
  13   ## updated.
  14   src = fetchFromGitHub {
  15     owner = "Cryolitia";
  16     repo = "ryzen_smu";
  17     rev = "ce1aa918efa33ca79998f0f7d467c04d4b07016c";
  18     hash = "sha256-s9SSmbL6ixWqZUKEhrZdxN4xoWgk+8ClZPoKq2FDAAE=";
  19   };
  20
  21   monitor-cpu = stdenv.mkDerivation {
  22     pname = "monitor-cpu";
  23     inherit version src;
  24
  25     makeFlags = [
  26       "-C userspace"
  27     ];
  28
  29     installPhase = ''
  30     runHook preInstall
  31
  32     install userspace/monitor_cpu -Dm755 -t $out/bin
  33
  34     runHook postInstall
  35   '';
  36   };
  37
  38 in
  39 stdenv.mkDerivation {
  40   pname = "ryzen-smu-${kernel.version}";
  41   inherit version src;
  42
  43   hardeningDisable = [ "pic" ];
  44
  45   nativeBuildInputs = kernel.moduleBuildDependencies;
  46
  47   makeFlags = [
  48     "TARGET=${kernel.modDirVersion}"
  49     "KERNEL_BUILD=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
  50   ];
  51
  52   installPhase = ''
  53     runHook preInstall
  54
  55     install ryzen_smu.ko -Dm444 -t $out/lib/modules/${kernel.modDirVersion}/kernel/drivers/ryzen_smu
  56     install ${monitor-cpu}/bin/monitor_cpu -Dm755 -t $out/bin
  57
  58     runHook postInstall
  59   '';
  60
  61   meta = with lib; {
  62     description = "Linux kernel driver that exposes access to the SMU (System Management Unit) for certain AMD Ryzen Processors";
  63     homepage = "https://gitlab.com/leogx9r/ryzen_smu";
  64     license = licenses.gpl2Plus;
  65     maintainers = with maintainers; [ Cryolitia phdyellow ];
  66     platforms = [ "x86_64-linux" ];
  67     mainProgram = "monitor_cpu";
  68   };
  69 }