pkgs/applications/blockchains/bisq-desktop/default.nix

   1 { stdenv
   2 , lib
   3 , makeWrapper
   4 , fetchurl
   5 , makeDesktopItem
   6 , copyDesktopItems
   7 , imagemagick
   8 , openjdk11
   9 , dpkg
  10 , writeScript
  11 , bash
  12 , stripJavaArchivesHook
  13 , tor
  14 , zip
  15 , xz
  16 , findutils
  17 }:
  18
  19 let
  20   bisq-launcher = args: writeScript "bisq-launcher" ''
  21     #! ${bash}/bin/bash
  22
  23     # This is just a comment to convince Nix that Tor is a
  24     # runtime dependency; The Tor binary is in a *.jar file,
  25     # whereas Nix only scans for hashes in uncompressed text.
  26     # ${bisq-tor}
  27
  28     classpath=@out@/lib/desktop.jar:@out@/lib/*
  29
  30     exec "${openjdk11}/bin/java" -Djpackage.app-version=@version@ -XX:MaxRAM=8g -Xss1280k -XX:+UseG1GC -XX:MaxHeapFreeRatio=10 -XX:MinHeapFreeRatio=5 -XX:+UseStringDeduplication -Djava.net.preferIPv4Stack=true -classpath $classpath ${args} bisq.desktop.app.BisqAppMain "$@"
  31   '';
  32
  33   bisq-tor = writeScript "bisq-tor" ''
  34     #! ${bash}/bin/bash
  35
  36     exec ${tor}/bin/tor "$@"
  37   '';
  38 in
  39 stdenv.mkDerivation rec {
  40   pname = "bisq-desktop";
  41   version = "1.9.17";
  42
  43   src = fetchurl {
  44     url = "https://github.com/bisq-network/bisq/releases/download/v${version}/Bisq-64bit-${version}.deb";
  45     sha256 = "1wqzgxsm9p6lh0bmvw0byaxx1r5v64d024jf1pg9mykb1dnnx0wy";
  46   };
  47
  48   nativeBuildInputs = [
  49     copyDesktopItems
  50     dpkg
  51     imagemagick
  52     makeWrapper
  53     stripJavaArchivesHook
  54     xz
  55     zip
  56     findutils
  57   ];
  58
  59   desktopItems = [
  60     (makeDesktopItem {
  61       name = "Bisq";
  62       exec = "bisq-desktop";
  63       icon = "bisq";
  64       desktopName = "Bisq ${version}";
  65       genericName = "Decentralized bitcoin exchange";
  66       categories = [ "Network" "P2P" ];
  67     })
  68
  69     (makeDesktopItem {
  70       name = "Bisq-hidpi";
  71       exec = "bisq-desktop-hidpi";
  72       icon = "bisq";
  73       desktopName = "Bisq ${version} (HiDPI)";
  74       genericName = "Decentralized bitcoin exchange";
  75       categories = [ "Network" "P2P" ];
  76     })
  77   ];
  78
  79   unpackPhase = ''
  80     dpkg -x $src .
  81   '';
  82
  83   buildPhase = ''
  84     # Replace the embedded Tor binary (which is in a Tar archive)
  85     # with one from Nixpkgs.
  86
  87     mkdir -p native/linux/x64/
  88     cp ${bisq-tor} ./tor
  89     tar --sort=name --mtime="@$SOURCE_DATE_EPOCH" -cJf native/linux/x64/tor.tar.xz tor
  90     tor_jar_file=$(find ./opt/bisq/lib/app -name "tor-binary-linux64-*.jar")
  91     zip -r $tor_jar_file native
  92   '';
  93
  94   installPhase = ''
  95     runHook preInstall
  96
  97     mkdir -p $out $out/bin
  98     cp -r opt/bisq/lib/app $out/lib
  99
 100     install -D -m 777 ${bisq-launcher ""} $out/bin/bisq-desktop
 101     substituteAllInPlace $out/bin/bisq-desktop
 102
 103     install -D -m 777 ${bisq-launcher "-Dglass.gtk.uiScale=2.0"} $out/bin/bisq-desktop-hidpi
 104     substituteAllInPlace $out/bin/bisq-desktop-hidpi
 105
 106     for n in 16 24 32 48 64 96 128 256; do
 107       size=$n"x"$n
 108       convert opt/bisq/lib/Bisq.png -resize $size bisq.png
 109       install -Dm644 -t $out/share/icons/hicolor/$size/apps bisq.png
 110     done;
 111
 112     runHook postInstall
 113   '';
 114
 115   passthru.updateScript = ./update.sh;
 116
 117   meta = with lib; {
 118     description = "Decentralized bitcoin exchange network";
 119     homepage = "https://bisq.network";
 120     changelog = "https://github.com/bisq-network/bisq/releases/tag/v${version}";
 121     sourceProvenance = with sourceTypes; [ binaryBytecode ];
 122     license = licenses.mit;
 123     maintainers = with maintainers; [ juaningan emmanuelrosa ];
 124     platforms = [ "x86_64-linux" ];
 125     # Requires OpenJFX 11 or 16, which are both EOL.
 126     broken = true;
 127   };
 128 }