pkgs/applications/blockchains/torq/default.nix

   1 { lib
   2 , buildGoModule
   3 , buildNpmPackage
   4 , fetchFromGitHub
   5 }:
   6
   7 let
   8   pname = "torq";
   9   version = "0.18.19";
  10
  11   src = fetchFromGitHub {
  12     owner = "lncapital";
  13     repo = pname;
  14     rev = "v${version}";
  15     hash = "sha256-qJIAH8SrB5a7j6ptorEm6fryZj63vDQIUQIgRsVn1us=";
  16   };
  17
  18   web = buildNpmPackage {
  19     pname = "${pname}-frontend";
  20     inherit version;
  21     src = "${src}/web";
  22     npmDepsHash = "sha256-WulYJE2pdVa5hquV/7UjR1z9PkglJXOq5fv8nLa4wos=";
  23
  24     # copied from upstream Dockerfile
  25     npmInstallFlags = [ "--legacy-peer-deps" ];
  26     TSX_COMPILE_ON_ERROR="true";
  27     ESLINT_NO_DEV_ERRORS="true";
  28
  29     # override npmInstallHook, we only care about the build/ directory
  30     installPhase = ''
  31       mkdir $out
  32       cp -r build/* $out/
  33     '';
  34   };
  35 in
  36 buildGoModule rec {
  37   inherit pname version src;
  38
  39   vendorHash = "sha256-bvisI589Gq9IdyJEqI+uzs3iDPOTUkq95P3n/KoFhF0=";
  40
  41   subPackages = [ "cmd/torq" ];
  42
  43   ldflags = [
  44     "-s"
  45     "-w"
  46     "-X github.com/lncapital/torq/build.version=v${version}"
  47   ];
  48
  49   postInstall = ''
  50     mkdir -p $out/web/build
  51     cp -r ${web}/* $out/web/build/
  52   '';
  53
  54   meta = with lib; {
  55     description = "Capital management tool for lightning network nodes";
  56     license = licenses.mit;
  57     homepage = "https://github.com/lncapital/torq";
  58     maintainers = with maintainers; [ mmilata prusnak ];
  59     mainProgram = "torq";
  60   };
  61 }