pkgs/applications/editors/greenfoot/default.nix

   1 { lib, stdenv, fetchurl, openjdk, glib, dpkg, wrapGAppsHook3 }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "greenfoot";
   5   version = "3.8.2";
   6
   7   src = fetchurl {
   8     # We use the deb here. First instinct might be to go for the "generic" JAR
   9     # download, but that is actually a graphical installer that is much harder
  10     # to unpack than the deb.
  11     url = "https://www.greenfoot.org/download/files/Greenfoot-linux-${builtins.replaceStrings ["."] [""] version}.deb";
  12     hash = "sha256-wpmgWtx2jTDjt+7p6HcjU/uy1PRmnAHpJ1rOYb+hV+U=";
  13   };
  14
  15   nativeBuildInputs = [ dpkg wrapGAppsHook3 ];
  16   buildInputs = [ glib ];
  17
  18   dontWrapGApps = true;
  19
  20   installPhase = ''
  21     runHook preInstall
  22
  23     mkdir -p $out
  24     cp -r usr/* $out
  25
  26     rm -r $out/share/greenfoot/jdk
  27     rm -r $out/share/greenfoot/javafx-*.jar
  28
  29     makeWrapper ${openjdk}/bin/java $out/bin/greenfoot \
  30       "''${gappsWrapperArgs[@]}" \
  31       --add-flags "-Dawt.useSystemAAFontSettings=on -Xmx512M \
  32                    --add-opens javafx.graphics/com.sun.glass.ui=ALL-UNNAMED \
  33                    -cp $out/share/greenfoot/boot.jar bluej.Boot \
  34                    -greenfoot=true -bluej.compiler.showunchecked=false \
  35                    -greenfoot.scenarios=$out/share/doc/Greenfoot/scenarios \
  36                    -greenfoot.url.javadoc=file://$out/share/doc/Greenfoot/API"
  37
  38     runHook postInstall
  39   '';
  40
  41   meta = with lib; {
  42     description = "Simple integrated development environment for Java";
  43     homepage = "https://www.greenfoot.org/";
  44     sourceProvenance = with sourceTypes; [ binaryBytecode ];
  45     license = licenses.gpl2ClasspathPlus;
  46     mainProgram = "greenfoot";
  47     maintainers = [ maintainers.chvp ];
  48     platforms = platforms.linux;
  49   };
  50 }