pkgs/applications/emulators/wibo/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , fetchzip
   5 , srcOnly
   6 , cmake
   7 , unzip
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "wibo";
  12   version = "0.4.2";
  13
  14   src = fetchFromGitHub {
  15     owner = "decompals";
  16     repo = "wibo";
  17     rev = version;
  18     hash = "sha256-oq/i0Hb2y5pwDEvaqSyC4+6LH1oUbvDZ/62l+V3S7Uk=";
  19   };
  20
  21   nativeBuildInputs = [
  22     cmake
  23     unzip
  24   ];
  25
  26   doCheck = false;
  27   # Test step from https://github.com/decompals/wibo/blob/main/.github/workflows/ci.yml
  28   checkPhase = let
  29     gc = srcOnly {
  30       name = "GC_WII_COMPILERS";
  31       src = fetchzip {
  32         url = "https://cdn.discordapp.com/attachments/727918646525165659/917185027656286218/GC_WII_COMPILERS.zip";
  33         hash = "sha256-o+UrmIbCsa74LxtLofT0DKrTRgT0qDK5/V7GsG2Zprc=";
  34         stripRoot = false;
  35       };
  36       meta.license = lib.licenses.unfree;
  37     };
  38   in lib.optionalString doCheck ''
  39     MWCIncludes=../test ./wibo ${gc}/GC/2.7/mwcceppc.exe -c ../test/test.c
  40     file test.o | grep "ELF 32-bit"
  41   '';
  42
  43   meta = with lib; {
  44     description = "Quick-and-dirty wrapper to run 32-bit windows EXEs on linux";
  45     longDescription = ''
  46       A minimal, low-fuss wrapper that can run really simple command-line
  47       32-bit Windows binaries on Linux - with less faff and less dependencies
  48       than WINE.
  49     '';
  50     homepage = "https://github.com/decompals/WiBo";
  51     license = licenses.mit;
  52     maintainers = with maintainers; [ r-burns ];
  53     platforms = [ "i686-linux" ];
  54     mainProgram = "wibo";
  55   };
  56 }