pkgs/applications/graphics/awesomebump/default.nix

   1 { mkDerivation, lib, fetchgit, qtbase, qmake, qtscript, flex, bison, qtdeclarative }:
   2
   3
   4 let
   5   version = "5.1";
   6
   7   src = fetchgit {
   8     url = "https://github.com/kmkolasinski/AwesomeBump.git";
   9     rev = "Winx32v${version}";
  10     sha256 = "1c8b9jki0v8kzkvsvyv7q1w3s7j40br6ph15hh2xi0a1mpwckq56";
  11     fetchSubmodules = true;
  12   };
  13
  14   qtnproperty = mkDerivation {
  15     name = "qtnproperty";
  16     inherit src;
  17     sourceRoot = "${src.name}/Sources/utils/QtnProperty";
  18     patches = [ ./qtnproperty-parallel-building.patch ];
  19     buildInputs = [ qtscript qtbase qtdeclarative ];
  20     nativeBuildInputs = [ qmake flex bison ];
  21     postInstall = ''
  22       install -D bin-linux/QtnPEG $out/bin/QtnPEG
  23     '';
  24   };
  25 in mkDerivation {
  26   pname = "awesomebump";
  27   inherit version;
  28
  29   inherit src;
  30
  31   buildInputs = [ qtbase qtscript qtdeclarative ];
  32
  33   nativeBuildInputs = [ qmake ];
  34
  35   preBuild = ''
  36     ln -sf ${qtnproperty}/bin/QtnPEG Sources/utils/QtnProperty/bin-linux/QtnPEG
  37   '';
  38
  39   dontWrapQtApps = true;
  40   postInstall = ''
  41     d=$out/libexec/AwesomeBump
  42
  43     mkdir -p $d
  44     cp -vr workdir/`cat workdir/current`/bin/AwesomeBump $d/
  45     cp -prd Bin/Configs Bin/Core $d/
  46
  47     # AwesomeBump expects to find Core and Configs in its current directory.
  48     makeQtWrapper $d/AwesomeBump $out/bin/AwesomeBump \
  49         --chdir "$d"
  50   '';
  51
  52   # $ cd Sources; qmake; make ../workdir/linux-g++-dgb-gl4/obj/glwidget.o
  53   # fatal error: properties/ImageProperties.peg.h: No such file or directory
  54   enableParallelBuilding = false;
  55
  56   meta = {
  57     homepage = "https://github.com/kmkolasinski/AwesomeBump";
  58     description = "Program to generate normal, height, specular or ambient occlusion textures from a single image";
  59     license = lib.licenses.gpl3Plus;
  60     maintainers = [ ];
  61     platforms = lib.platforms.linux;
  62     mainProgram = "AwesomeBump";
  63   };
  64 }