pkgs/applications/graphics/trimage/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4
   5 , python3
   6 , installShellFiles
   7 , makeWrapper
   8 , wrapQtAppsHook
   9
  10 , advancecomp
  11 , jpegoptim
  12 , optipng
  13 , pngcrush
  14 }:
  15
  16 let
  17   pythonEnv = python3.withPackages (ps: with ps; [ pyqt5 ]);
  18   binPath = lib.makeBinPath [
  19     advancecomp
  20     jpegoptim
  21     optipng
  22     pngcrush
  23   ];
  24 in
  25 stdenv.mkDerivation {
  26   pname = "trimage";
  27   version = "1.0.7-dev";
  28
  29   src = fetchFromGitHub {
  30     owner = "Kilian";
  31     repo = "Trimage";
  32     rev = "ad74684272a31eee6af289cc59fd90fd962d2806";
  33     hash = "sha256-jdcGGTqr3f3Xnp6thYmASQYiZh9nagLUTmlFnJ5Hqmc=";
  34   };
  35
  36   nativeBuildInputs = [
  37     installShellFiles
  38     makeWrapper
  39     wrapQtAppsHook
  40   ];
  41
  42   dontWrapQtApps = true;
  43
  44   installPhase = ''
  45     runHook preInstall
  46
  47     mkdir $out
  48     cp -R trimage $out
  49
  50     installManPage doc/trimage.1
  51     install -Dm444 desktop/trimage.desktop -t $out/share/applications
  52     install -Dm444 desktop/trimage.svg -t $out/share/icons/hicolor/scalable/apps
  53
  54     makeWrapper ${pythonEnv}/bin/python $out/bin/trimage \
  55           --add-flags "$out/trimage/trimage.py" \
  56           --prefix PATH : ${binPath} \
  57           "''${qtWrapperArgs[@]}"
  58
  59     runHook postInstall
  60   '';
  61
  62   meta = {
  63     description = "Cross-platform tool for optimizing PNG and JPG files";
  64     homepage = "https://github.com/Kilian/Trimage";
  65     license = lib.licenses.mit;
  66     mainProgram = "trimage";
  67     maintainers = with lib.maintainers; [ tomasajt ];
  68   };
  69 }