pkgs/applications/misc/bambu-studio/orca-slicer.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   bambu-studio,
   5   opencv,
   6 }:
   7 bambu-studio.overrideAttrs (
   8   finalAttrs: previousAttrs: {
   9     version = "2.1.1";
  10     pname = "orca-slicer";
  11
  12     src = fetchFromGitHub {
  13       owner = "SoftFever";
  14       repo = "OrcaSlicer";
  15       rev = "v${finalAttrs.version}";
  16       hash = "sha256-7fusdSYpZb4sYl5L/+81PzMd42Nsejj+kCZsq0f7eIk=";
  17     };
  18
  19     patches =
  20       previousAttrs.patches
  21       ++ [
  22         # FIXME: only required for 2.1.1, can be removed in the next version
  23         ./0002-fix-build-for-gcc-13.diff
  24
  25         ./dont-link-opencv-world.patch
  26       ];
  27
  28     buildInputs =
  29       previousAttrs.buildInputs
  30       ++ [
  31         opencv
  32       ];
  33
  34     preFixup = ''
  35       gappsWrapperArgs+=(
  36         # Fixes blackscreen dialogs
  37         --set WEBKIT_DISABLE_COMPOSITING_MODE 1
  38       )
  39     '';
  40
  41     # needed to prevent collisions between the LICENSE.txt files of
  42     # bambu-studio and orca-slicer.
  43     postInstall = ''
  44       mv $out/LICENSE.txt $out/share/OrcaSlicer/LICENSE.txt
  45     '';
  46
  47     meta = with lib; {
  48       description = "G-code generator for 3D printers (Bambu, Prusa, Voron, VzBot, RatRig, Creality, etc.)";
  49       homepage = "https://github.com/SoftFever/OrcaSlicer";
  50       license = licenses.agpl3Only;
  51       maintainers = with maintainers; [
  52         zhaofengli
  53         ovlach
  54         pinpox
  55       ];
  56       mainProgram = "orca-slicer";
  57       platforms = platforms.linux;
  58     };
  59   }
  60 )