pkgs/applications/misc/inochi2d/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   substituteAll,
   6   callPackage,
   7 }:
   8
   9 # Note for maintainers:
  10 #
  11 # These packages are only allowed to be packaged under the the condition that we
  12 # - patch source/creator/config.d to not point to upstream's bug tracker
  13 # - use the "barebones" configuration to remove the mascot and logo from the build
  14 #
  15 # We have received permission by the owner to go ahead with the packaging, as we have met all the criteria
  16 # https://github.com/NixOS/nixpkgs/pull/288841#issuecomment-1950247467
  17
  18 let
  19   mkGeneric = builderArgs: callPackage ./generic.nix { inherit builderArgs; };
  20 in
  21 {
  22   inochi-creator = mkGeneric rec {
  23     pname = "inochi-creator";
  24     appname = "Inochi Creator";
  25     version = "0.8.6";
  26
  27     src = fetchFromGitHub {
  28       owner = "Inochi2D";
  29       repo = "inochi-creator";
  30       rev = "v${version}";
  31       hash = "sha256-9d3j5ZL6rGOjN1GUpCIfbjby0mNMvOK7BJbHYgwLY2k=";
  32     };
  33
  34     dubLock = ./creator-dub-lock.json;
  35
  36     patches = [
  37       # Upstream asks that we change the bug tracker URL to not point to the upsteam bug tracker
  38       (substituteAll {
  39         src = ./support-url.patch;
  40         assignees = "TomaSajt"; # should be a comma separated list of the github usernames of the maintainers
  41       })
  42       # Change how duplicate locales differentiate themselves (the store paths were too long)
  43       ./translations.patch
  44     ];
  45
  46     meta = {
  47       # darwin has slightly different build steps
  48       broken = stdenv.hostPlatform.isDarwin;
  49       changelog = "https://github.com/Inochi2D/inochi-creator/releases/tag/${src.rev}";
  50       description = "An open source editor for the Inochi2D puppet format";
  51     };
  52   };
  53
  54   inochi-session = mkGeneric rec {
  55     pname = "inochi-session";
  56     appname = "Inochi Session";
  57     version = "0.8.7";
  58
  59     src = fetchFromGitHub {
  60       owner = "Inochi2D";
  61       repo = "inochi-session";
  62       rev = "v${version}";
  63       hash = "sha256-FcgzTCpD+L50MsPP90kfL6h6DEUtiYkUV1xKww1pQfg=";
  64     };
  65
  66     patches = [
  67       # Dynamically load Lua to get around the linker error on aarch64-linux.
  68       # https://github.com/Inochi2D/inochi-session/pull/60
  69       ./session-dynamic-lua.patch
  70     ];
  71
  72     dubLock = ./session-dub-lock.json;
  73
  74     preFixup = ''
  75       patchelf $out/share/inochi-session/inochi-session --add-needed cimgui.so
  76     '';
  77
  78     dontStrip = true; # symbol lookup error: undefined symbol: , version
  79
  80     meta = {
  81       # darwin has slightly different build steps
  82       broken = stdenv.hostPlatform.isDarwin;
  83       changelog = "https://github.com/Inochi2D/inochi-session/releases/tag/${src.rev}";
  84       description = "An application that allows streaming with Inochi2D puppets";
  85     };
  86   };
  87 }