pkgs/applications/misc/mepo/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromSourcehut
   4 , SDL2
   5 , SDL2_gfx
   6 , SDL2_image
   7 , SDL2_ttf
   8 , busybox
   9 , curl
  10 , findutils
  11 , geoclue2-with-demo-agent
  12 , gpsd
  13 , jq
  14 , makeWrapper
  15 , ncurses
  16 , pkg-config
  17 , util-linux
  18 , xwininfo
  19 , zenity
  20 , zig_0_12
  21 }:
  22
  23 stdenv.mkDerivation (finalAttrs: {
  24   pname = "mepo";
  25   version = "1.2.1";
  26
  27   src = fetchFromSourcehut {
  28     owner = "~mil";
  29     repo = "mepo";
  30     rev = finalAttrs.version;
  31     hash = "sha256-Ii5E9TgUxzlVIdkKS/6RtasOETeclMm1yoU86gs4hB8=";
  32   };
  33
  34   nativeBuildInputs = [
  35     pkg-config
  36     zig_0_12.hook
  37     makeWrapper
  38   ];
  39
  40   buildInputs = [
  41     curl
  42     SDL2
  43     SDL2_gfx
  44     SDL2_image
  45     SDL2_ttf
  46     jq
  47     ncurses
  48   ];
  49
  50   doCheck = true;
  51
  52   postInstall = ''
  53     install -d $out/share/man/man1
  54     $out/bin/mepo -docman > $out/share/man/man1/mepo.1
  55   '';
  56
  57   postFixup = ''
  58     substituteInPlace $out/bin/mepo_ui_menu_user_pin_updater.sh \
  59       --replace-fail /usr/libexec/geoclue-2.0 ${geoclue2-with-demo-agent}/libexec/geoclue-2.0
  60     substituteInPlace $out/bin/mepo_ui_central_menu.sh \
  61       --replace-fail "grep mepo_" "grep '^\.mepo_\|^mepo_'" \
  62       --replace-fail " ls " " ls -a " #circumvent wrapping for script detection
  63     for program in $out/bin/* ; do
  64       wrapProgram $program \
  65         --suffix PATH : $out/bin:${lib.makeBinPath ([
  66           busybox
  67           curl
  68           findutils
  69           gpsd
  70           jq
  71           ncurses
  72           util-linux
  73           xwininfo
  74           zenity
  75         ])}
  76     done
  77   '';
  78
  79   meta = {
  80     homepage = "https://mepo.milesalan.com";
  81     description = "Fast, simple, and hackable OSM map viewer";
  82     longDescription = ''
  83       Mepo is a fast, simple, and hackable OSM map viewer for desktop & mobile
  84       Linux devices (like the PinePhone, Librem 5, postmarketOS devices etc.)
  85       and both environment's various user interfaces (Wayland & X
  86       inclusive). Environments supported include Phosh, Sxmo, Plasma Mobile,
  87       desktop X, and desktop Wayland. Mepo works both offline and online,
  88       features a minimalist both touch/mouse and keyboard compatible interface,
  89       and offers a UNIX-philosophy inspired underlying design, exposing a
  90       powerful command language called Mepolang capable of being scripted to
  91       provide things like custom bounding-box search scripts, bookmarks, and
  92       more.
  93     '';
  94     license = lib.licenses.gpl3Plus;
  95     maintainers = with lib.maintainers; [ sikmir McSinyx laalsaas ];
  96     platforms = lib.platforms.linux;
  97   };
  98 })