pkgs/applications/misc/sway-contrib/default.nix

   1 { lib, stdenvNoCC
   2 , fetchFromGitHub
   3 , coreutils
   4 , makeWrapper
   5 , sway-unwrapped
   6 , installShellFiles
   7 , wl-clipboard
   8 , libnotify
   9 , slurp
  10 , grim
  11 , jq
  12 , gnugrep
  13 , bash
  14
  15 , python3Packages
  16 }:
  17
  18 let
  19   version = "0-unstable-2024-03-19";
  20   src = fetchFromGitHub {
  21     owner = "OctopusET";
  22     repo = "sway-contrib";
  23     rev = "5d33a290e3cac3f0fed38ff950939da28e3ebfd7";
  24     hash = "sha256-2qYxkXowSSzVcpsPO4JoUqaH/VUkOOWu1RKFXp1CXGs=";
  25   };
  26
  27   meta = with lib; {
  28     homepage = "https://github.com/OctopusET/sway-contrib";
  29     license = licenses.mit;
  30     platforms = platforms.all;
  31   };
  32 in
  33 {
  34
  35 grimshot = stdenvNoCC.mkDerivation {
  36   inherit version src;
  37
  38   pname = "grimshot";
  39
  40   dontBuild = true;
  41   dontConfigure = true;
  42
  43   outputs = [ "out" "man" ];
  44
  45   strictDeps = true;
  46   nativeBuildInputs = [ makeWrapper installShellFiles ];
  47   buildInputs = [ bash ];
  48   installPhase = ''
  49     installManPage grimshot.1
  50     installShellCompletion --cmd grimshot grimshot-completion.bash
  51
  52     install -Dm 0755 grimshot $out/bin/grimshot
  53     wrapProgram $out/bin/grimshot --set PATH \
  54       "${lib.makeBinPath [
  55         sway-unwrapped
  56         wl-clipboard
  57         coreutils
  58         libnotify
  59         slurp
  60         grim
  61         jq
  62         gnugrep
  63         ] }"
  64   '';
  65
  66   doInstallCheck = true;
  67
  68   installCheckPhase = ''
  69     # check always returns 0
  70     if [[ $($out/bin/grimshot check | grep "NOT FOUND") ]]; then false
  71     else
  72       echo "grimshot check passed"
  73     fi
  74   '';
  75
  76   meta = with lib; meta // {
  77     description = "Helper for screenshots within sway";
  78     maintainers = with maintainers; [ evils ];
  79     mainProgram = "grimshot";
  80   };
  81 };
  82
  83
  84 inactive-windows-transparency = let
  85   # long name is long
  86   lname = "inactive-windows-transparency";
  87 in python3Packages.buildPythonApplication {
  88   inherit version src;
  89
  90   pname = "sway-${lname}";
  91
  92   format = "other";
  93   dontBuild = true;
  94   dontConfigure = true;
  95
  96   propagatedBuildInputs = [ python3Packages.i3ipc ];
  97
  98   installPhase = ''
  99     install -Dm 0755 $src/${lname}.py $out/bin/${lname}.py
 100   '';
 101
 102   meta = with lib; meta // {
 103     description = "It makes inactive sway windows transparent";
 104     mainProgram = "${lname}.py";
 105     maintainers = with maintainers; [
 106       evils # packaged this as a side-effect of grimshot but doesn't use it
 107     ];
 108   };
 109 };
 110
 111 }