pkgs/applications/misc/wofi-emoji/default.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   fetchFromGitHub,
   6   jq,
   7   wofi,
   8   wtype,
   9   wl-clipboard,
  10 }:
  11
  12 let
  13   emojiJSON = fetchurl {
  14     url = "https://raw.githubusercontent.com/muan/emojilib/v3.0.11/dist/emoji-en-US.json";
  15     hash = "sha256-WHqCSNgDzc6ZASdVrwPvsU4MtBcYLKDp2D2Hykrq1sI=";
  16   };
  17 in
  18 stdenv.mkDerivation rec {
  19   pname = "wofi-emoji";
  20   version = "1.0.0";
  21
  22   src = fetchFromGitHub {
  23     owner = "Zeioth";
  24     repo = "wofi-emoji";
  25     rev = "v${version}";
  26     hash = "sha256-wLZK7RcDxxlYuu27WNj+SoRoBiCqk9whp4Fyg0SOoPA=";
  27   };
  28
  29   nativeBuildInputs = [ jq ];
  30   buildInputs = [
  31     wofi
  32     wtype
  33     wl-clipboard
  34   ];
  35
  36   postPatch = ''
  37     substituteInPlace build.sh \
  38       --replace 'curl ${emojiJSON.url}' 'cat ${emojiJSON}'
  39     substituteInPlace wofi-emoji \
  40       --replace 'wofi' '${wofi}/bin/wofi' \
  41       --replace 'wtype' '${wtype}/bin/wtype' \
  42       --replace 'wl-copy' '${wl-clipboard}/bin/wl-copy'
  43   '';
  44
  45   buildPhase = ''
  46     runHook preBuild
  47
  48     bash build.sh
  49
  50     runHook postBuild
  51   '';
  52
  53   installPhase = ''
  54     runHook preInstall
  55
  56     mkdir -p $out/bin
  57     cp wofi-emoji $out/bin
  58
  59     runHook postInstall
  60   '';
  61
  62   meta = {
  63     description = "Simple emoji selector for Wayland using wofi and wl-clipboard";
  64     homepage = "https://github.com/Zeioth/wofi-emoji";
  65     license = lib.licenses.mit;
  66     maintainers = with lib.maintainers; [ johnrtitor ymarkus ];
  67     platforms = lib.platforms.all;
  68     mainProgram = "wofi-emoji";
  69   };
  70 }