pkgs/applications/misc/xpdf/default.nix

   1 { enableGUI ? true
   2 , enablePDFtoPPM ? true
   3 , enablePrinting ? true
   4 , lib, stdenv, fetchzip, cmake, makeDesktopItem
   5 , zlib, libpng, cups ? null, freetype ? null
   6 , qtbase ? null, qtsvg ? null, wrapQtAppsHook
   7 }:
   8
   9 assert enableGUI -> qtbase != null && qtsvg != null && freetype != null;
  10 assert enablePDFtoPPM -> freetype != null;
  11 assert enablePrinting -> cups != null;
  12
  13 stdenv.mkDerivation rec {
  14   pname = "xpdf";
  15   version = "4.05";
  16
  17   src = fetchzip {
  18     urls = [
  19       "https://dl.xpdfreader.com/xpdf-${version}.tar.gz"
  20       "https://dl.xpdfreader.com/old/xpdf-${version}.tar.gz"
  21     ];
  22     hash = "sha256-LBxKSrXTdoulZDjPiyYMaJr63jFHHI+VCgVJx310i/w=";
  23   };
  24
  25   # Fix "No known features for CXX compiler", see
  26   # https://cmake.org/pipermail/cmake/2016-December/064733.html and the note at
  27   # https://cmake.org/cmake/help/v3.10/command/cmake_minimum_required.html
  28   postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
  29     substituteInPlace CMakeLists.txt --replace \
  30         'cmake_minimum_required(VERSION 2.8.12)' 'cmake_minimum_required(VERSION 3.1.0)'
  31     '';
  32
  33   nativeBuildInputs =
  34     [ cmake ]
  35     ++ lib.optional enableGUI wrapQtAppsHook;
  36
  37   cmakeFlags = ["-DSYSTEM_XPDFRC=/etc/xpdfrc" "-DA4_PAPER=ON" "-DOPI_SUPPORT=ON"]
  38     ++ lib.optional (!enablePrinting) "-DXPDFWIDGET_PRINTING=OFF";
  39
  40   buildInputs = [ zlib libpng ] ++
  41     lib.optional enableGUI qtbase ++
  42     lib.optional enablePrinting cups ++
  43     lib.optional enablePDFtoPPM freetype;
  44
  45   desktopItem = makeDesktopItem {
  46     name = "xpdf";
  47     desktopName = "Xpdf";
  48     comment = "Views Adobe PDF files";
  49     icon = "xpdf";
  50     exec = "xpdf %f";
  51     categories = [ "Office" ];
  52   };
  53
  54   postInstall = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
  55     install -Dm644 ${desktopItem}/share/applications/xpdf.desktop -t $out/share/applications
  56     install -Dm644 $src/xpdf-qt/xpdf-icon.svg $out/share/pixmaps/xpdf.svg
  57   '';
  58
  59   meta = with lib; {
  60     homepage = "https://www.xpdfreader.com";
  61     description = "Viewer for Portable Document Format (PDF) files";
  62     longDescription = ''
  63       XPDF includes multiple tools for viewing and processing PDF files.
  64         xpdf:      PDF viewer (with Graphical Interface)
  65         pdftotext: converts PDF to text
  66         pdftops:   converts PDF to PostScript
  67         pdftoppm:  converts PDF pages to netpbm (PPM/PGM/PBM) image files
  68         pdftopng:  converts PDF pages to PNG image files
  69         pdftohtml: converts PDF to HTML
  70         pdfinfo:   extracts PDF metadata
  71         pdfimages: extracts raw images from PDF files
  72         pdffonts:  lists fonts used in PDF files
  73         pdfdetach: extracts attached files from PDF files
  74     '';
  75     license = with licenses; [ gpl2Only gpl3Only ];
  76     platforms = platforms.unix;
  77     maintainers = with maintainers; [ sikmir ];
  78     knownVulnerabilities = [
  79       "CVE-2023-26930"
  80       "CVE-2024-2971"
  81       "CVE-2024-3247"
  82       "CVE-2024-3248"
  83       "CVE-2024-3900"
  84       "CVE-2024-4141"
  85       "CVE-2024-4568"
  86       "CVE-2024-4976"
  87     ];
  88   };
  89 }