pkgs/applications/networking/mullvad/mullvad.nix

   1 { lib
   2 , stdenv
   3 , rustPlatform
   4 , fetchFromGitHub
   5 , pkg-config
   6 , protobuf
   7 , makeWrapper
   8 , git
   9 , dbus
  10 , libnftnl
  11 , libmnl
  12 , libwg
  13 , enableOpenvpn ? true
  14 , openvpn-mullvad
  15 , shadowsocks-rust
  16 , installShellFiles
  17 }:
  18 rustPlatform.buildRustPackage rec {
  19   pname = "mullvad";
  20   version = "2024.4";
  21
  22   src = fetchFromGitHub {
  23     owner = "mullvad";
  24     repo = "mullvadvpn-app";
  25     rev = version;
  26     hash = "sha256-d7poR1NnvqaPutXLFizpQnyipl+38N1Qe2zVXeV7v1Q=";
  27   };
  28
  29   cargoLock = {
  30     lockFile = ./Cargo.lock;
  31     outputHashes = {
  32       "udp-over-tcp-0.3.0" = "sha256-5PeaM7/zhux1UdlaKpnQ2yIdmFy1n2weV/ux9lSRha4=";
  33     };
  34   };
  35
  36   checkFlags = "--skip=version_check";
  37
  38   nativeBuildInputs = [
  39     pkg-config
  40     protobuf
  41     makeWrapper
  42     git
  43     installShellFiles
  44   ];
  45
  46   buildInputs = [
  47     dbus.dev
  48     libnftnl
  49     libmnl
  50   ];
  51
  52   # talpid-core wants libwg.a in build/lib/{triple}
  53   preBuild = ''
  54     dest=build/lib/${stdenv.hostPlatform.config}
  55     mkdir -p $dest
  56     ln -s ${libwg}/lib/libwg.a $dest
  57   '';
  58
  59   postInstall = ''
  60     compdir=$(mktemp -d)
  61     for shell in bash zsh fish; do
  62       $out/bin/mullvad shell-completions $shell $compdir
  63     done
  64     installShellCompletion --cmd mullvad \
  65       --bash $compdir/mullvad.bash \
  66       --zsh $compdir/_mullvad \
  67       --fish $compdir/mullvad.fish
  68   '';
  69
  70   postFixup =
  71     # Place all binaries in the 'mullvad-' namespace, even though these
  72     # specific binaries aren't used in the lifetime of the program.
  73     ''
  74       for bin in relay_list translations-converter tunnel-obfuscation; do
  75         mv "$out/bin/$bin" "$out/bin/mullvad-$bin"
  76       done
  77     '' +
  78     # Files necessary for OpenVPN tunnels to work.
  79     lib.optionalString enableOpenvpn ''
  80       mkdir -p $out/share/mullvad
  81       cp dist-assets/ca.crt $out/share/mullvad
  82       ln -s ${openvpn-mullvad}/bin/openvpn $out/share/mullvad
  83       ln -s ${shadowsocks-rust}/bin/sslocal $out/share/mullvad
  84       ln -s $out/lib/libtalpid_openvpn_plugin.so $out/share/mullvad
  85     '' +
  86     # Set the directory where Mullvad will look for its resources by default to
  87     # `$out/share`, so that we can avoid putting the files in `$out/bin` --
  88     # Mullvad defaults to looking inside the directory its binary is located in
  89     # for its resources.
  90     ''
  91       wrapProgram $out/bin/mullvad-daemon \
  92         --set-default MULLVAD_RESOURCE_DIR "$out/share/mullvad"
  93     '';
  94
  95   passthru = {
  96     inherit libwg;
  97     inherit openvpn-mullvad;
  98   };
  99
 100   meta = with lib; {
 101     description = "Mullvad VPN command-line client tools";
 102     homepage = "https://github.com/mullvad/mullvadvpn-app";
 103     license = licenses.gpl3Only;
 104     maintainers = with maintainers; [ cole-h ];
 105   };
 106 }