pkgs/applications/office/mendeley/default.nix

   1 { lib
   2 , fetchurl
   3 , appimageTools
   4 , gconf
   5 , imagemagick
   6 }:
   7
   8 let
   9   pname = "mendeley";
  10   version = "2.120.0";
  11
  12   executableName = "${pname}-reference-manager";
  13
  14   src = fetchurl {
  15     url = "https://static.mendeley.com/bin/desktop/mendeley-reference-manager-${version}-x86_64.AppImage";
  16     hash = "sha256-yKHrTcIiNhsLMfwNQNSLE2mAQLsDFxhTYdper3a8oM8=";
  17   };
  18
  19   appimageContents = appimageTools.extractType2 {
  20     inherit pname version src;
  21   };
  22 in appimageTools.wrapType2 {
  23   inherit pname version src;
  24
  25   extraInstallCommands = ''
  26     mv $out/bin/$pname $out/bin/${executableName}
  27     install -m 444 -D ${appimageContents}/${executableName}.desktop $out/share/applications/${executableName}.desktop
  28     ${imagemagick}/bin/convert ${appimageContents}/${executableName}.png -resize 512x512 ${pname}_512.png
  29     install -m 444 -D ${pname}_512.png $out/share/icons/hicolor/512x512/apps/${executableName}.png
  30
  31     substituteInPlace $out/share/applications/${executableName}.desktop \
  32       --replace 'Exec=AppRun' 'Exec=${executableName}'
  33   '';
  34
  35   meta = with lib; {
  36     homepage = "https://www.mendeley.com";
  37     description = "Reference manager and academic social network";
  38     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  39     license = licenses.unfree;
  40     platforms = [ "x86_64-linux" ];
  41     maintainers  = with maintainers; [ atila ];
  42     mainProgram = "mendeley-reference-manager";
  43   };
  44
  45 }