pkgs/applications/science/biology/kalign/default.nix

   1 { lib
   2 , stdenv
   3 , cmake
   4 , fetchFromGitHub
   5 , llvmPackages
   6 , enableSse4_1 ? stdenv.hostPlatform.sse4_1Support
   7 , enableAvx ? stdenv.hostPlatform.avxSupport
   8 , enableAvx2 ? stdenv.hostPlatform.avx2Support
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "kalign";
  13   version = "3.4.0";
  14
  15   src = fetchFromGitHub {
  16     owner = "TimoLassmann";
  17     repo = "kalign";
  18     rev = "refs/tags/v${finalAttrs.version}";
  19     hash = "sha256-QcFNaCTqj6CFiOzQ6ezfBL0mu8PDU11hyNdkcsLOPzA=";
  20   };
  21
  22   nativeBuildInputs = [
  23     cmake
  24   ];
  25
  26   buildInputs = lib.optionals stdenv.cc.isClang [
  27     llvmPackages.openmp
  28   ];
  29
  30   cmakeFlags =
  31     # these flags are ON by default
  32     lib.optional (!enableSse4_1) "-DENABLE_SSE=OFF"
  33     ++ lib.optional (!enableAvx) "-DENABLE_AVX=OFF"
  34     ++ lib.optional (!enableAvx2) "-DENABLE_AVX2=OFF";
  35
  36   doCheck = true;
  37
  38   meta = {
  39     description = "Fast multiple sequence alignment program";
  40     mainProgram = "kalign";
  41     homepage = "https://github.com/TimoLassmann/kalign";
  42     changelog = "https://github.com/TimoLassmann/kalign/releases/tag/${lib.removePrefix "refs/tags/" finalAttrs.src.rev}";
  43     license = lib.licenses.gpl3Plus;
  44     maintainers = with lib.maintainers; [ natsukium ];
  45     platforms = lib.platforms.unix;
  46   };
  47 })