pkgs/applications/science/logic/coq/default.nix

   1 # - coqide compilation can be disabled by setting buildIde to false
   2 # - The csdp program used for the Micromega tactic is statically referenced.
   3 #   However, coq can build without csdp by setting it to null.
   4 #   In this case some Micromega tactics will search the user's path for the csdp program and will fail if it is not found.
   5 # - The exact version can be specified through the `version` argument to
   6 #   the derivation; it defaults to the latest stable version.
   7
   8 { lib, stdenv, fetchzip, fetchurl, writeText, pkg-config, gnumake42
   9 , customOCamlPackages ? null
  10 , ocamlPackages_4_05, ocamlPackages_4_09, ocamlPackages_4_10, ocamlPackages_4_12
  11 , ocamlPackages_4_14
  12 , ncurses
  13 , buildIde ? null # default is true for Coq < 8.14 and false for Coq >= 8.14
  14 , glib, adwaita-icon-theme, wrapGAppsHook3, makeDesktopItem, copyDesktopItems
  15 , csdp ? null
  16 , version, coq-version ? null
  17 }@args:
  18 let
  19   lib = import ../../../../build-support/coq/extra-lib.nix { inherit (args) lib; };
  20
  21   release = {
  22    "8.5pl1".sha256     = "1976ki5xjg2r907xj9p7gs0kpdinywbwcqlgxqw75dgp0hkgi00n";
  23    "8.5pl2".sha256     = "109rrcrx7mz0fj7725kjjghfg5ydwb24hjsa5hspa27b4caah7rh";
  24    "8.5pl3".sha256     = "15c3rdk59nifzihsp97z4vjxis5xmsnrvpb86qiazj143z2fmdgw";
  25    "8.6.0".sha256      = "148mb48zpdax56c0blfi7v67lx014lnmrvxxasi28hsibyz2lvg4";
  26    "8.6.0".rev         = "V8.6";
  27    "8.6.1".sha256      = "0llrxcxwy5j87vbbjnisw42rfw1n1pm5602ssx64xaxx3k176g6l";
  28    "8.7.0".sha256      = "1h18b7xpnx3ix9vsi5fx4zdcbxy7bhra7gd5c5yzxmk53cgf1p9m";
  29    "8.7.1".sha256      = "0gjn59jkbxwrihk8fx9d823wjyjh5m9gvj9l31nv6z6bcqhgdqi8";
  30    "8.7.2".sha256      = "0a0657xby8wdq4aqb2xsxp3n7pmc2w4yxjmrb2l4kccs1aqvaj4w";
  31    "8.8.0".sha256      = "13a4fka22hdxsjk11mgjb9ffzplfxyxp1sg5v1c8nk1grxlscgw8";
  32    "8.8.1".sha256      = "1hlf58gwazywbmfa48219amid38vqdl94yz21i11b4map6jfwhbk";
  33    "8.8.2".sha256      = "1lip3xja924dm6qblisk1bk0x8ai24s5xxqxphbdxj6djglj68fd";
  34    "8.9.0".sha256      = "1dkgdjc4n1m15m1p724hhi5cyxpqbjw6rxc5na6fl3v4qjjfnizh";
  35    "8.9.1".sha256      = "1xrq6mkhpq994bncmnijf8jwmwn961kkpl4mwwlv7j3dgnysrcv2";
  36    "8.10.0".sha256     = "138jw94wp4mg5dgjc2asn8ng09ayz1mxdznq342n0m469j803gzg";
  37    "8.10.1".sha256     = "072v2zkjzf7gj48137wpr3c9j0hg9pdhlr5l8jrgrwynld8fp7i4";
  38    "8.10.2".sha256     = "0znxmpy71bfw0p6x47i82jf5k7v41zbz9bdpn901ysn3ir8l3wrz";
  39    "8.11.0".sha256     = "1rfdic6mp7acx2zfwz7ziqk12g95bl9nyj68z4n20a5bcjv2pxpn";
  40    "8.11.1".sha256     = "0qriy9dy36dajsv5qmli8gd6v55mah02ya334nw49ky19v7518m0";
  41    "8.11.2".sha256     = "0f77ccyxdgbf1nrj5fa8qvrk1cyfy06fv8gj9kzfvlcgn0cf48sa";
  42    "8.12.0".sha256     = "18dc7k0piv6v064zgdadpw6mkkxk7j663hb3svgj5236fihjr0cz";
  43    "8.12.1".sha256     = "1rkcyjjrzcqw9xk93hsq0vvji4f8r5iq0f739mghk60bghkpnb7q";
  44    "8.12.2".sha256     = "18gscfm039pqhq4msq01nraig5dm9ab98bjca94zldf8jvdv0x2n";
  45    "8.13.0".sha256     = "1l2c63vskp8kiyxiyi5rpgbmnv67ysn3y4lybd6nj0li5llibifi";
  46    "8.13.1".sha256     = "15drjcqhsgwqnv02bbidyhk316ypyhz1pxfz2gwsalci9svhkz0v";
  47    "8.13.2".sha256     = "14d4alp35hngvga9m7cfp5d1nl62xdj0nm4811f2jjblk86gxxk4";
  48    "8.14.0".sha256     = "0yxjx9kq9bfpk31dc1c6a0pz0827fz7jmrcwwd4n7dc07yi0arq8";
  49    "8.14.1".sha256     = "0xdqiabgm4lrm6d7lw544zd8xwb1cdcavsxvwwlqq6yid2rl2yli";
  50    "8.15.0".sha256     = "sha256:0q7jl3bn0d1v9cwdkxykw4frccww6wbh1p8hdrfqw489mkxmh5jh";
  51    "8.15.1".sha256     = "sha256:1janvmnk3czimp0j5qmnfwx6509vhpjc2q7lcza1bc6dm6kn8n42";
  52    "8.15.2".sha256     = "sha256:0qibbvzrhsvs6w3zpkhyclndp29jnr6bs9i5skjlpp431jdjjfqd";
  53    "8.16.0".sha256   = "sha256-3V6kL9j2rn5FHBxq1mtmWWTZS9X5cAyvtUsS6DaM+is=";
  54    "8.16.1".sha256   = "sha256-n7830+zfZeyYHEOGdUo57bH6bb2/SZs8zv8xJhV+iAc=";
  55    "8.17.0".sha256   = "sha256-TGwm7S6+vkeZ8cidvp8pkiAd9tk008jvvPvYgfEOXhM=";
  56    "8.17.1".sha256   = "sha256-x+RwkbxMg9aR0L3WSCtpIz8jwA5cJA4tXAtHMZb20y4=";
  57    "8.18.0".sha256   = "sha256-WhiBs4nzPHQ0R24xAdM49kmxSCPOxiOVMA1iiMYunz4=";
  58    "8.19.0".sha256   = "sha256-ixsYCvCXpBHqJ71hLQklphlwoOO3i/6w2PJjllKqf9k=";
  59    "8.19.1".sha256   = "sha256-kmZ8Uk8jpzjOd67aAPp3C+vU2oNaBw9pr7+Uixcgg94=";
  60    "8.19.2".sha256   = "sha256-q+i07JsMZp83Gqav6v1jxsgPLN7sPvp5/oszVnavmz0=";
  61    "8.20.0".sha256   = "sha256-WFpZlA6CzFVAruPhWcHQI7VOBVhrGLdFzWrHW0DTSl0=";
  62   };
  63   releaseRev = v: "V${v}";
  64   fetched = import ../../../../build-support/coq/meta-fetch/default.nix
  65     { inherit lib stdenv fetchzip fetchurl; }
  66     { inherit release releaseRev; location = { owner = "coq"; repo = "coq";}; }
  67     args.version;
  68   version = fetched.version;
  69   coq-version = args.coq-version or (if version != "dev" then lib.versions.majorMinor version else "dev");
  70   coqAtLeast = v: coq-version == "dev" || lib.versionAtLeast coq-version v;
  71   buildIde = args.buildIde or (!coqAtLeast "8.14");
  72   ideFlags = lib.optionalString (buildIde && !coqAtLeast "8.10")
  73     "-lablgtkdir ${ocamlPackages.lablgtk}/lib/ocaml/*/site-lib/lablgtk2 -coqide opt";
  74   csdpPatch = lib.optionalString (csdp != null) ''
  75     substituteInPlace plugins/micromega/sos.ml --replace "; csdp" "; ${csdp}/bin/csdp"
  76     substituteInPlace plugins/micromega/coq_micromega.ml --replace "System.is_in_system_path \"csdp\"" "true"
  77   '';
  78   ocamlPackages = if customOCamlPackages != null then customOCamlPackages
  79     else lib.switch coq-version [
  80       { case = lib.versions.range "8.16" "8.18"; out = ocamlPackages_4_14; }
  81       { case = lib.versions.range "8.14" "8.15"; out = ocamlPackages_4_12; }
  82       { case = lib.versions.range "8.11" "8.13"; out = ocamlPackages_4_10; }
  83       { case = lib.versions.range "8.7" "8.10";  out = ocamlPackages_4_09; }
  84       { case = lib.versions.range "8.5" "8.6";   out = ocamlPackages_4_05; }
  85     ] ocamlPackages_4_14;
  86   ocamlNativeBuildInputs = [ ocamlPackages.ocaml ocamlPackages.findlib ]
  87     ++ lib.optional (coqAtLeast "8.14") ocamlPackages.dune_3;
  88   ocamlPropagatedBuildInputs = [ ]
  89     ++ lib.optional (!coqAtLeast "8.10") ocamlPackages.camlp5
  90     ++ lib.optional (!coqAtLeast "8.13") ocamlPackages.num
  91     ++ lib.optional (coqAtLeast "8.13") ocamlPackages.zarith;
  92 self = stdenv.mkDerivation {
  93   pname = "coq";
  94   inherit (fetched) version src;
  95
  96   passthru = {
  97     inherit coq-version;
  98     inherit ocamlPackages ocamlNativeBuildInputs;
  99     inherit ocamlPropagatedBuildInputs;
 100     # For compatibility
 101     inherit (ocamlPackages) ocaml camlp5 findlib num ;
 102     emacsBufferSetup = pkgs: ''
 103       ; Propagate coq paths to children
 104       (inherit-local-permanent coq-prog-name "${self}/bin/coqtop")
 105       (inherit-local-permanent coq-dependency-analyzer "${self}/bin/coqdep")
 106       (inherit-local-permanent coq-compiler "${self}/bin/coqc")
 107       ; If the coq-library path was already set, re-set it based on our current coq
 108       (when (fboundp 'get-coq-library-directory)
 109         (inherit-local-permanent coq-library-directory (get-coq-library-directory))
 110         (coq-prog-args))
 111       (mapc (lambda (arg)
 112         (when (file-directory-p (concat arg "/lib/coq/${coq-version}/user-contrib"))
 113           (setenv "COQPATH" (concat (getenv "COQPATH") ":" arg "/lib/coq/${coq-version}/user-contrib")))) '(${lib.concatStringsSep " " (map (pkg: "\"${pkg}\"") pkgs)}))
 114       ; TODO Abstract this pattern from here and nixBufferBuilders.withPackages!
 115       (defvar nixpkgs--coq-buffer-count 0)
 116       (when (eq nixpkgs--coq-buffer-count 0)
 117         (make-variable-buffer-local 'nixpkgs--is-nixpkgs-coq-buffer)
 118         (defun nixpkgs--coq-inherit (buf)
 119           (inherit-local-inherit-child buf)
 120           (with-current-buffer buf
 121             (setq nixpkgs--coq-buffer-count (1+ nixpkgs--coq-buffer-count))
 122             (add-hook 'kill-buffer-hook 'nixpkgs--decrement-coq-buffer-count nil t))
 123           buf)
 124         ; When generating a scomint buffer, do inherit-local inheritance and make it a nixpkgs-coq buffer
 125         (defun nixpkgs--around-scomint-make (orig &rest r)
 126           (if nixpkgs--is-nixpkgs-coq-buffer
 127               (progn
 128                 (advice-add 'get-buffer-create :filter-return #'nixpkgs--coq-inherit)
 129                 (apply orig r)
 130                 (advice-remove 'get-buffer-create #'nixpkgs--coq-inherit))
 131             (apply orig r)))
 132         (advice-add 'scomint-make :around #'nixpkgs--around-scomint-make)
 133         ; When we have no more coq buffers, tear down the buffer handling
 134         (defun nixpkgs--decrement-coq-buffer-count ()
 135           (setq nixpkgs--coq-buffer-count (1- nixpkgs--coq-buffer-count))
 136           (when (eq nixpkgs--coq-buffer-count 0)
 137             (advice-remove 'scomint-make #'nixpkgs--around-scomint-make)
 138             (fmakunbound 'nixpkgs--around-scomint-make)
 139             (fmakunbound 'nixpkgs--coq-inherit)
 140             (fmakunbound 'nixpkgs--decrement-coq-buffer-count))))
 141       (setq nixpkgs--coq-buffer-count (1+ nixpkgs--coq-buffer-count))
 142       (add-hook 'kill-buffer-hook 'nixpkgs--decrement-coq-buffer-count nil t)
 143       (setq nixpkgs--is-nixpkgs-coq-buffer t)
 144       (inherit-local 'nixpkgs--is-nixpkgs-coq-buffer)
 145     '';
 146   };
 147
 148   nativeBuildInputs = [ pkg-config ]
 149     ++ ocamlNativeBuildInputs
 150     ++ lib.optional buildIde copyDesktopItems
 151     ++ lib.optional (buildIde && coqAtLeast "8.10") wrapGAppsHook3
 152     ++ lib.optional (!coqAtLeast "8.6") gnumake42;
 153   buildInputs = [ ncurses ]
 154     ++ lib.optionals buildIde
 155       (if coqAtLeast "8.10"
 156        then [ ocamlPackages.lablgtk3-sourceview3 glib adwaita-icon-theme ]
 157        else [ ocamlPackages.lablgtk ])
 158   ;
 159
 160   propagatedBuildInputs = ocamlPropagatedBuildInputs;
 161
 162   postPatch = ''
 163     UNAME=$(type -tp uname)
 164     RM=$(type -tp rm)
 165     substituteInPlace tools/beautify-archive --replace "/bin/rm" "$RM"
 166     ${lib.optionalString (!coqAtLeast "8.7") "substituteInPlace configure.ml --replace \"md5 -q\" \"md5sum\""}
 167     ${csdpPatch}
 168   '';
 169
 170   setupHook = writeText "setupHook.sh" ''
 171     addCoqPath () {
 172       if test -d "''$1/lib/coq/${coq-version}/user-contrib"; then
 173         export COQPATH="''${COQPATH-}''${COQPATH:+:}''$1/lib/coq/${coq-version}/user-contrib/"
 174       fi
 175     }
 176
 177     addEnvHooks "$targetOffset" addCoqPath
 178   '';
 179
 180   preConfigure = if coqAtLeast "8.10" then ''
 181     patchShebangs dev/tools/
 182   '' else ''
 183     configureFlagsArray=(
 184       ${ideFlags}
 185     )
 186   '';
 187
 188   prefixKey = "-prefix ";
 189
 190   buildFlags = [ "revision" "coq" ] ++ lib.optional buildIde "coqide" ++ lib.optional (!coqAtLeast "8.14") "bin/votour";
 191   enableParallelBuilding = true;
 192
 193   createFindlibDestdir = true;
 194
 195   desktopItems = lib.optional buildIde (makeDesktopItem {
 196     name = "coqide";
 197     exec = "coqide";
 198     icon = "coq";
 199     desktopName = "CoqIDE";
 200     comment = "Graphical interface for the Coq proof assistant";
 201     categories = [ "Development" "Science" "Math" "IDE" "GTK" ];
 202   });
 203
 204   postInstall = let suffix = lib.optionalString (coqAtLeast "8.14") "-core"; in lib.optionalString (!coqAtLeast "8.17") ''
 205     cp bin/votour $out/bin/
 206   '' + ''
 207     ln -s $out/lib/coq${suffix} $OCAMLFIND_DESTDIR/coq${suffix}
 208   '' + lib.optionalString (coqAtLeast "8.14") ''
 209     ln -s $out/lib/coqide-server $OCAMLFIND_DESTDIR/coqide-server
 210   '' + lib.optionalString buildIde ''
 211     mkdir -p "$out/share/pixmaps"
 212     ln -s "$out/share/coq/coq.png" "$out/share/pixmaps/"
 213   '';
 214
 215   meta = with lib; {
 216     description = "Coq proof assistant";
 217     longDescription = ''
 218       Coq is a formal proof management system.  It provides a formal language
 219       to write mathematical definitions, executable algorithms and theorems
 220       together with an environment for semi-interactive development of
 221       machine-checked proofs.
 222     '';
 223     homepage = "https://coq.inria.fr";
 224     license = licenses.lgpl21;
 225     branch = coq-version;
 226     maintainers = with maintainers; [ roconnor thoughtpolice vbgl Zimmi48 ];
 227     platforms = platforms.unix;
 228     mainProgram = "coqide";
 229   };
 230 }; in
 231 if coqAtLeast "8.17" then self.overrideAttrs(_: {
 232   buildPhase = ''
 233     runHook preBuild
 234     make dunestrap
 235     dune build -p coq-core,coq-stdlib,coq,coqide-server${lib.optionalString buildIde ",coqide"} -j $NIX_BUILD_CORES
 236     runHook postBuild
 237   '';
 238   installPhase = ''
 239     runHook preInstall
 240     dune install --prefix $out coq-core coq-stdlib coq coqide-server${lib.optionalString buildIde " coqide"}
 241     runHook postInstall
 242   '';
 243 }) else self