pkgs/applications/science/logic/tlaplus/toolbox.nix

   1 { lib
   2 , fetchzip
   3 , makeShellWrapper
   4 , makeDesktopItem
   5 , stdenv
   6 , gtk3
   7 , libXtst
   8 , glib
   9 , zlib
  10 , wrapGAppsHook3
  11 }:
  12
  13 let
  14   desktopItem = makeDesktopItem rec {
  15     name = "TLA+Toolbox";
  16     exec = "tla-toolbox";
  17     icon = "tla-toolbox";
  18     comment = "IDE for TLA+";
  19     desktopName = name;
  20     genericName = comment;
  21     categories = [ "Development" ];
  22     startupWMClass = "TLA+ Toolbox";
  23   };
  24
  25
  26 in
  27 stdenv.mkDerivation rec {
  28   pname = "tla-toolbox";
  29   version = "1.7.1";
  30   src = fetchzip {
  31     url = "https://tla.msr-inria.inria.fr/tlatoolbox/products/TLAToolbox-${version}-linux.gtk.x86_64.zip";
  32     sha256 = "02a2y2mkfab5cczw8g604m61h4xr0apir49zbd1aq6mmgcgngw80";
  33   };
  34
  35   buildInputs = [ gtk3 ];
  36
  37   nativeBuildInputs = [
  38     makeShellWrapper
  39     wrapGAppsHook3
  40   ];
  41
  42   dontWrapGApps = true;
  43
  44   installPhase = ''
  45     runHook preInstall
  46
  47     mkdir -p "$out/bin"
  48     cp -r "$src" "$out/toolbox"
  49     chmod -R +w "$out/toolbox"
  50
  51     fixupPhase
  52     gappsWrapperArgsHook
  53
  54     patchelf \
  55       --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
  56       "$out/toolbox/toolbox"
  57
  58     patchelf \
  59       --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
  60       --set-rpath "${lib.makeLibraryPath [ zlib ]}:$(patchelf --print-rpath $(find "$out/toolbox" -name java))" \
  61       "$(find "$out/toolbox" -name java)"
  62
  63     patchelf \
  64       --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
  65       "$(find "$out/toolbox" -name jspawnhelper)"
  66
  67     makeShellWrapper $out/toolbox/toolbox $out/bin/tla-toolbox \
  68       --chdir "$out/toolbox" \
  69       --add-flags "-data ~/.tla-toolbox" \
  70       --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ gtk3 libXtst glib zlib ]}"  \
  71       "''${gappsWrapperArgs[@]}"
  72
  73     echo -e "\nCreating TLA Toolbox icons..."
  74     pushd "$src"
  75     for icon_in in $(find . -path "./plugins/*/icons/full/etool16/tla_launch_check_wiz_*.png")
  76     do
  77       icon_size=$(echo $icon_in | grep -Po "wiz_\K[0-9]+")
  78       icon_out="$out/share/icons/hicolor/$icon_size""x$icon_size/apps/tla-toolbox.png"
  79       mkdir -p "$(dirname $icon_out)"
  80       cp "$icon_in" "$icon_out"
  81     done
  82     popd
  83
  84     echo -e "\nCreating TLA Toolbox desktop entry..."
  85     cp -r "${desktopItem}/share/applications"* "$out/share/applications"
  86
  87     runHook postInstall
  88   '';
  89
  90   meta = {
  91     homepage = "http://research.microsoft.com/en-us/um/people/lamport/tla/toolbox.html";
  92     description = "IDE for the TLA+ tools";
  93     mainProgram = "tla-toolbox";
  94     longDescription = ''
  95       Integrated development environment for the TLA+ tools, based on Eclipse. You can use it
  96       to create and edit your specs, run the PlusCal translator, view the pretty-printed
  97       versions of your modules, run the TLC model checker, and run TLAPS, the TLA+ proof system.
  98     '';
  99     # http://lamport.azurewebsites.net/tla/license.html
 100     license = with lib.licenses; [ mit ];
 101     sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
 102     platforms = [ "x86_64-linux" ];
 103     maintainers = [ ];
 104   };
 105 }