pkgs/applications/version-management/pijul/default.nix

   1 { lib, stdenv
   2 , fetchCrate
   3 , rustPlatform
   4 , installShellFiles
   5 , pkg-config
   6 , libsodium
   7 , openssl
   8 , xxHash
   9 , darwin
  10 , gitImportSupport ? true
  11 , libgit2 ? null
  12 }:
  13
  14 rustPlatform.buildRustPackage rec {
  15   pname = "pijul";
  16   version = "1.0.0-beta.9";
  17
  18   src = fetchCrate {
  19     inherit version pname;
  20     hash = "sha256-jy0mzgLw9iWuoWe2ictMTL3cHnjJ5kzs6TAK+pdm28g=";
  21   };
  22
  23   cargoHash = "sha256-iXGvb4qmZK7Sjbf/Jkyzj+nhpZFV3ngjtJfz6x/8z2s=";
  24
  25   doCheck = false;
  26   nativeBuildInputs = [ installShellFiles pkg-config ];
  27   buildInputs = [ openssl libsodium xxHash ]
  28     ++ (lib.optionals gitImportSupport [ libgit2 ])
  29     ++ (lib.optionals stdenv.hostPlatform.isDarwin (with darwin.apple_sdk.frameworks; [
  30       CoreServices Security SystemConfiguration
  31     ]));
  32
  33   buildFeatures = lib.optional gitImportSupport "git";
  34
  35   postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  36     installShellCompletion --cmd pijul \
  37       --bash <($out/bin/pijul completion bash) \
  38       --fish <($out/bin/pijul completion fish) \
  39       --zsh <($out/bin/pijul completion zsh)
  40   '';
  41
  42   meta = with lib; {
  43     description = "Distributed version control system";
  44     homepage = "https://pijul.org";
  45     license = with licenses; [ gpl2Plus ];
  46     maintainers = with maintainers; [ gal_bolle dywedir fabianhjr ];
  47     mainProgram = "pijul";
  48   };
  49 }