pkgs/applications/video/bombono/default.nix

   1 { lib, stdenv
   2 , fetchFromGitHub
   3 , pkg-config
   4 , fetchpatch
   5 , fetchpatch2
   6 , scons
   7 , boost
   8 , dvdauthor
   9 , dvdplusrwtools
  10 , enca
  11 , cdrkit
  12 , ffmpeg_6
  13 , gettext
  14 , gtk2
  15 , gtkmm2
  16 , libdvdread
  17 , libxmlxx
  18 , mjpegtools
  19 , wrapGAppsHook3
  20 }:
  21
  22 stdenv.mkDerivation {
  23   pname = "bombono";
  24   version = "1.2.4-unstable-2022-02-06";
  25
  26   src = fetchFromGitHub {
  27     owner = "bombono-dvd";
  28     repo = "bombono-dvd";
  29     rev = "8680f5803314e4bcfbdae44f555c47ad345dae72";
  30     hash = "sha256-8AxXIvShH4HwlPZWAszku33rts13HiNoRsHiLYdZAHA=";
  31   };
  32
  33   patches = [
  34     (fetchpatch {
  35       name = "bombono-dvd-1.2.4-scons3.patch";
  36       url = "https://svnweb.mageia.org/packages/cauldron/bombono-dvd/current/SOURCES/bombono-dvd-1.2.4-scons-python3.patch?revision=1447925&view=co&pathrev=1484457";
  37       sha256 = "sha256-5OKBWrRZvHem2MTdAObfdw76ig3Z4ZdDFtq4CJoJISA=";
  38     })
  39
  40     # Fix compilation errors having ffmpeg 2:5.1
  41     # https://github.com/bombono-dvd/bombono-dvd/pull/28
  42     (fetchpatch2 {
  43       url = "https://github.com/bombono-dvd/bombono-dvd/commit/9f2cde1ddc22705bf58264739685086755b2138b.patch?full_index=1";
  44       hash = "sha256-ks6c04HEYF4nPfSOjzG+dUt9v7ZmNBb0XH6byPYqX5I=";
  45     })
  46   ];
  47
  48   postPatch = ''
  49     substituteInPlace src/mbase/SConscript \
  50       --replace "lib_mbase_env['CPPDEFINES']" "list(lib_mbase_env['CPPDEFINES'])"
  51   '';
  52
  53   nativeBuildInputs = [ wrapGAppsHook3 scons pkg-config gettext ];
  54
  55   buildInputs = [
  56     boost
  57     dvdauthor
  58     dvdplusrwtools
  59     enca
  60     ffmpeg_6
  61     gtk2
  62     gtkmm2
  63     libdvdread
  64     libxmlxx
  65     mjpegtools
  66   ];
  67
  68   prefixKey = "PREFIX=";
  69
  70   enableParallelBuilding = true;
  71
  72   postInstall = ''
  73     # fix iso authoring
  74     install -Dt  $out/share/bombono/resources/scons_authoring tools/scripts/SConsTwin.py
  75
  76     wrapProgram $out/bin/bombono-dvd --prefix PATH : ${lib.makeBinPath [ ffmpeg_6 dvdauthor cdrkit ]}
  77   '';
  78
  79   meta = with lib; {
  80     description = "DVD authoring program for personal computers";
  81     homepage = "https://www.bombono.org/";
  82     license = licenses.gpl2Only;
  83     maintainers = with maintainers; [ symphorien ];
  84     platforms = platforms.linux;
  85   };
  86 }