pkgs/applications/video/glaxnimate/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitLab
   4 , fetchpatch
   5 , cmake
   6 , zlib
   7 , potrace
   8 , ffmpeg
   9 , libarchive
  10 , python3
  11 , qtbase
  12 , qttools
  13 , wrapQtAppsHook
  14 , testers
  15 , qtsvg
  16 , qtimageformats
  17   # For the tests
  18 , glaxnimate # Call itself, for the tests
  19 , xvfb-run
  20 }:
  21 let
  22   # TODO: try to add a python library, see toPythonModule in doc/languages-frameworks/python.section.md
  23   python3WithLibs = python3.withPackages (ps: with ps; [
  24     # In data/lib/python-lottie/requirements.txt
  25     numpy
  26     pillow
  27     cairosvg
  28     fonttools
  29     grapheme
  30     opencv4
  31     pyqt5
  32     qscintilla
  33     # Not sure if needed, but appears in some files
  34     pyyaml
  35     requests
  36     pybind11
  37   ]);
  38 in
  39 stdenv.mkDerivation rec {
  40   pname = "glaxnimate";
  41   version = "0.5.4";
  42
  43   src = fetchFromGitLab {
  44     owner = "mattbas";
  45     repo = "${pname}";
  46     rev = version;
  47     hash = "sha256-8oHJCQdP2xxSSDM0MDkSrG89WgCtMKm1AKlddnq3gig=";
  48     fetchSubmodules = true;
  49   };
  50
  51   patches = [
  52     # Backport fix for newer ffmpeg
  53     # FIXME: remove in next update
  54     (fetchpatch {
  55       url = "https://invent.kde.org/graphics/glaxnimate/-/commit/4fb2b67a0f0ce2fbffb6fe9f87c3bf7914c8a602.patch";
  56       hash = "sha256-QjCnscGa7n+zwrImA4mbQiTQb9jmDGm8Y/7TK8jZXvM=";
  57     })
  58   ];
  59
  60   nativeBuildInputs = [
  61     cmake
  62     wrapQtAppsHook
  63     qttools
  64   ];
  65
  66   buildInputs = [
  67     zlib
  68     potrace
  69     # Upstream asks for libav dependency, which is fulfilled by ffmpeg
  70     ffmpeg
  71     libarchive
  72     qtbase
  73     qttools
  74     qtsvg
  75     qtimageformats
  76     python3WithLibs
  77   ];
  78
  79   # Translation needs to be separately compiled
  80   # https://gitlab.com/mattbas/glaxnimate/-/issues/648
  81   buildFlags = [ "translations" ];
  82
  83   qtWrapperArgs = [ ''--prefix PATH : ${python3WithLibs}/bin'' ];
  84
  85   passthru.tests.version = lib.optionalAttrs stdenv.hostPlatform.isLinux (testers.testVersion {
  86     package = glaxnimate;
  87     command = "${xvfb-run}/bin/xvfb-run glaxnimate --version";
  88   });
  89
  90   meta = with lib; {
  91     homepage = "https://gitlab.com/mattbas/glaxnimate";
  92     description = "Simple vector animation program";
  93     license = licenses.gpl3;
  94     maintainers = with maintainers; [ tobiasBora ];
  95     mainProgram = "glaxnimate";
  96   };
  97 }