pkgs/applications/video/kodi/addons/certifi/default.nix

   1 { lib, rel, buildKodiAddon, fetchzip, addonUpdateScript, cacert }:
   2 buildKodiAddon rec {
   3   pname = "certifi";
   4   namespace = "script.module.certifi";
   5   version = "2023.5.7";
   6
   7   src = fetchzip {
   8     url = "https://mirrors.kodi.tv/addons/${lib.toLower rel}/${namespace}/${namespace}-${version}.zip";
   9     sha256 = "sha256-NQbjx+k9fnQMYLLMR5+N5NSuDcXEzZjlhGPA3qSmjfI=";
  10   };
  11
  12   patches = [
  13     # Add support for NIX_SSL_CERT_FILE
  14     ./env.patch
  15   ];
  16
  17   postPatch = ''
  18     # Use our system-wide ca-bundle instead of the bundled one
  19     ln -snvf "${cacert}/etc/ssl/certs/ca-bundle.crt" "lib/certifi/cacert.pem"
  20   '';
  21
  22   propagatedNativeBuildInputs = [
  23     # propagate cacerts setup-hook to set up `NIX_SSL_CERT_FILE`
  24     cacert
  25   ];
  26
  27   passthru = {
  28     pythonPath = "lib";
  29     updateScript = addonUpdateScript {
  30       attrPath = "kodi.packages.certifi";
  31     };
  32   };
  33
  34   meta = with lib; {
  35     homepage = "https://certifi.io";
  36     description = "Python package for providing Mozilla's CA Bundle";
  37     license = licenses.mpl20;
  38     maintainers = teams.kodi.members;
  39   };
  40 }